String Variables not setting in For Loop

Question

I think I have a simple problem. I have a file where I'm trying to format the output into columns. I think I found a way to do it here but the string1 and string2 variables are not setting. Any ideas? I'm not familiar with Windows scripting and come from Linux where it's much easier.

Make this:

                 San Disk USB Drive, 10-12-2013
                 Superdrive Disk USB Drive, 10-11-2013

look like this:

                 San Disk USB Drive            10-12-2013
                 Superdrive Disk USB Drive     10-11-2013

Code I'm using to read the text file:

    FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ temp_sorted_usb_history.txt"`) do (
        set "var=%%a"
        SETLOCAL EnableDelayedExpansion
        set "var=!var:*:=!"
        echo(!var!
        for /F "tokens=1,2 delims=," %%b in ("!var!") do (
                echo %%b%%c
                set string1=%%b
                set string2=%%c
                set string1="%string1%                                        "
                set string2="%string2%                                        "
                echo !string1:~-40! !string2:~-40!
            )
        ping -n 4 -w 1 127.0.0.1 >NUL
        ENDLOCAL
    )

The problem is that I can't get the string variables to set.

try this: FOR /F "delims=" %%a in ('findstr /n "^" "temp_sorted_usb_history.txt"'). — Endoro
– Endoro, Commented Jun 11, 2013 at 17:06
possible duplicate of Batch file variables initialized in a for loop — Andriy M
– Andriy M, Commented Jun 11, 2013 at 17:58
Thanks, it was actually correctly capturing the line, the vars in the script were not setting. I used this instead "or /F "tokens=1,2 delims=," %%b in (temp_sorted_usb_history.txt) do". Thanks for responding! — Mike Q
– Mike Q, Commented Jun 12, 2013 at 14:21

Aacini · Accepted Answer · 2013-06-11 17:43:46Z

3

I don't understand why you are using findstr command. This is the way I would do that:

setlocal EnableDelayedExpansion
for /F "tokens=1,2 delims=," %%b in (temp_sorted_usb_history.txt) do (
   echo %%b%%c
   set "string1=%%b                                        "
   set "string2=%%c                                        "
   echo !string1:~0,40! !string2:~0,40!
)
ping -n 4 -w 1 127.0.0.1 >NUL

answered Jun 11, 2013 at 17:43

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Mike Q Over a year ago

Thanks! I read that people were using findstr to get around some issue which is not obvious to me. Here is the link to the reasoning for using it: stackoverflow.com/questions/206114/….

Aacini Over a year ago

findstr is mainly used to read empty lines or to enumerate lines, but your problem have not these points, isn't it?

Mike Q Over a year ago

Thanks, btw, the script is running great now!

foxidrive · Accepted Answer · 2013-06-11 17:25:23Z

1

With setlocal enabledelayedexpansion

variables in parentheses are referred to as !variable! instead of %variable%

You have two strings that do not use !variable! notation, and they should.

You could however use this style of syntax where the quotes are not actually part of the variable, and eliminate the two other lines.

            set "string1=%%b                            "
            set "string2=%%c                            "

Another option might be to have the date first, and sorting by date would be simple.

@echo off
for /F "tokens=1,2 delims=," %%b in (temp_sorted_usb_history.txt) do (
echo %%c - %%b
)

edited Jun 11, 2013 at 17:25

answered Jun 11, 2013 at 17:09

foxidrive

41.4k11 gold badges61 silver badges71 bronze badges

1 Comment

Mike Q Over a year ago

Thanks! I'm still trying to figure out the differences ... Linux it doesn't matter ..

Collectives™ on Stack Overflow

String Variables not setting in For Loop

2 Answers 2

3 Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related