Justifying text using awk

If you know the target width in advance, you can get basic justification by redistributing the spaces in each line:

#!/usr/bin/awk -f

BEGIN {
    if (width == 0) width = 80
}

NF <= 1 { print }

NF > 1 {
    nbchar = 0
    for (i = 1; i <= NF; i++) {
        nbchar += length($i)
    }
    nbspc = width - nbchar
    spcpf = int(nbspc / (NF - 1))
    for (i = 1; i < NF; i++) {
        printf $i
        spaces = (NF == 2 || i == NF - 1) ? nbspc : spcpf
        if (spaces < 1) spaces = 1
        for (j = 0; j < spaces; j++) {
            printf " "
        }
        nbspc -= spaces
    }
    print $NF
}

(with a default width of 80; override with -v width=...).

This works as follows:

• lines with no or one field are output as-is;
• each line with two or more fields is processed:
  • the number of non-field-separator characters is counted (nbchar);
  • this determines the number of spaces to distribute (ncspc);
  • dividing that by the number of fields minus one gives the number of spaces to print between each field (rounded down in spcpf);
  • each field is printed, except the last one; then the appropriate number of spaces is printed — we always ensure there's at least one, and we pick spcpf, except on lines with only two fields, or if we're printing the second last field, in which case it's however many spaces are left (nbspc is adjusted to keep track);
  • finally the last field is printed, with a new line.

If you want to target the existing text's width, initialize width using something like this:

awk 'length > max { max = length }; END { print max }'

(I don't know of a foolproof way of resetting the input stream in awk — you could always specify that it's a file and adapt the script accordingly.)

This produces

This is a   text
that          is
not  distributed
evenly in a file

with width 16 (the existing text's width), or

This   is   a   text
that              is
not      distributed
evenly  in  a   file

with width 20, or

This is a text
that      is
not distributed
evenly in a file

with width 12 (lines overflow then).

Here you go.

    cat file1.txt 
    This is a text
    that is
    not distributed
    evenly in a file

You said "lines is spreaded evenly,", so injecting "\t" tab-delimited , should do it for you.

   cat file1.txt | awk '{print $1 "\t" $2 "\t" $3  "\t" $4 }'

 > file2.txt 

Result:

    cat file2.txt 
    This    is  a   text
    that    is      
    not distributed     
    evenly  in  a   file