1

I'm learning Perl. I am able to iterate over a JSON collection using a Perl hash data structure like this using sample data. However, the actual data contains some elements that are causing either the error Not a HASH reference or Can't use string ("...") as a HASH ref while "strict refs" in use.

Here's a simplified example of problematic data that is giving me trouble:

{
    "0y7vfr1234": {
        "username": "[email protected]",
        "password": "some-random-password123",
        "uri": "ww1.example.com",
        "index": 14
    },
    "v2rbz1568": {
        "username": "[email protected]",
        "password": "some-random-password125",
        "uri": "ww3.example.com",
        "index": 29
    },
    "active": "0y7vfr1234",
    "0zjk1156": {
        "username": "[email protected]",
        "password": "some-random-password124",
        "uri": "ww2.example.com",
        "index": 38
    },
    "logging": {
        "active": true
    }
}

I am only concerned with the data elements that have a uri. I want to skip over the others. How would I do that?

After trying dozens of things that did not work (and only led to new or different errors), here is how I finally got around the errors. However, I assume there is a much better way to do it than using ref().

#!/usr/bin/perl
use JSON;
use utf8;
use Data::Dumper;
use strict; use warnings;

my $data = '{
        "0y7vfr1234": {
            "username": "[email protected]",
            "password": "some-random-password123",
            "uri": "ww1.example.com",
            "index": 14
        },
        "v2rbz1568": {
            "username": "[email protected]",
            "password": "some-random-password125",
            "uri": "ww3.example.com",
            "index": 29
        },
        "active": "0y7vfr1234",
        "0zjk1156": {
            "username": "[email protected]",
            "password": "some-random-password124",
            "uri": "ww2.example.com",
            "index": 38
        },
        "logging": {
            "active": true
        }
    }';

my $json = decode_json($data);

foreach my $key (keys %$json) {

    if ( ref( $json->{$key} ) !~ m/HASH/ ) {
            print "[" . ref( $json->{$key} ) . "]: skipping\n";
            next;
    }

    if ( ! exists $json->{$key}->{uri} ) {
        print "Not a server. It's type is:  [" . ref($json->{$key}) . "]\n";
        print "Without curly braces: $json->$key\n";
        print Dumper($json->{$key});
        print "With curly braces: $json->{$key}\n";
        next;
    }

    print "checking $json->{$key}->{uri}\n";
    # do some other stuff
}

The code more or less works as is, but I'm not happy with it... or my understanding of it.

My questions are:

  1. What is the right way to iterate over "mixed" data like my JSON without encountering errors?
  2. What is a good way to display some information about the elements that I skip? I tried various things in the code (Data Dumper, printing without curly braces, etc.) and none of them are satisfactory. Is there a better way I can show information about what was skipped (without causing an error, of course)?
  3. Why does the above code $json->{$key}->{uri} also work without the arrow like this: $json->{$key}{uri}?

I'm using perl 5, version 30 on Linux.

Improve this question
1
  • 1
    1. ref is OK. You can also use reftype from Scalar::Util for blessed references. 2. use Data::Dumper or write your own, better variant. 3. because TIMTOWTDI. All of $a->{b}->{c}, $$a{b}{c}, $a->{b}{c}, $$a{b}->{c} mean exactly the same. 4. better ask such questions on stackoverflow Commented Dec 17, 2019 at 21:24

2 Answers 2

Reset to default
1

Like this:

#!/usr/bin/perl   
use JSON; use utf8;
use strict; use warnings;

my $data = '{
        "0y7vfr1234": {
            "username": "[email protected]",
            "password": "some-random-password123",
            "uri": "ww1.example.com",
            "index": 14
        },
        "v2rbz1568": {
            "username": "[email protected]",
            "password": "some-random-password125",
            "uri": "ww3.example.com",
            "index": 29
        },
        "active": "0y7vfr1234",
        "0zjk1156": {
            "username": "[email protected]",
            "password": "some-random-password124",
            "uri": "ww2.example.com",
            "index": 38
        },
        "logging": {
            "active": true
        }
}';   
my $json = decode_json($data);
while (my ($key, $value) = each(%$json)) {
    next unless ref $value;            # skip if $value isn't a ref
    next if scalar (keys %$value) < 2;  # skip if the numbers of HASH keys < 2
    print "$value->{uri}\n";
}
Improve this answer
1
  • 1
    Very nice. Thank you. Commented Dec 17, 2019 at 22:05
0

An alternative is to use 'keys' to get a list of the hash keys and look with foreach as shown below.

#!/usr/bin/perl
use JSON; use utf8;
use strict; use warnings;

my $data = '{
        "0y7vfr1234": {
            "username": "[email protected]",
            "password": "some-random-password123",
            "uri": "ww1.example.com",
            "index": 14
        },
        "v2rbz1568": {
            "username": "[email protected]",
            "password": "some-random-password125",
            "uri": "ww3.example.com",
            "index": 29
        },
        "active": "0y7vfr1234",
        "0zjk1156": {
            "username": "[email protected]",
            "password": "some-random-password124",
            "uri": "ww2.example.com",
            "index": 38
        },
        "logging": {
            "active": true
        },
        "293829jdkwm": {
            "uri": "ww4.example.com"
        }
}';

my $json = decode_json($data);

foreach my $key ( keys (%$json) ){
  next unless ref $json->{$key};          # skip if the value for $key is not an object
  next unless exists $json->{$key}{uri};  # skip if the object for $key does not have a 'uri' property

  printf ("%s -> %s\n", $key, $json->{$key}{uri});
}
Improve this answer
1
  • Your answer could be improved with additional supporting information. Please edit to add further details, such as citations or documentation, so that others can confirm that your answer is correct. You can find more information on how to write good answers in the help center. Commented May 7 at 18:34

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.