awk -- replace once after immediate pattern in same line!

Question

We have a 1.5MB file.
One particular line has about 160000 characters.
In the line we need to change "false" into "true" only once immediate after PATTERN.

Following awk only changes first occurrence.
But we need the change only after "PATTERN" once.

awk '/PATTERN.*false/ {sub("false", "true")} {print}' file

Our file contains:

...
colorA is false colorB is false PATTERN is false colorC is false colorD is false
...

File need to have:

...
colorA is false colorB is false PATTERN is true colorC is false colorD is false
...

How we can arrange awk command to fit our need?

THANKS IN ADVANCE!

Will PATTERN always be without a whitespace? After PATTERN, will there always be " is true" (exactly), when you have to change it to " is false"? — chaos
– chaos, Commented Feb 7, 2020 at 8:16
PATTERN Will have no whitespace. Between PATTERN and true have unknown number of words. — Amelia
– Amelia, Commented Feb 7, 2020 at 8:20
That last part is going to be a problem, because awk regular expressions are greedy. That means a RegExp PATTERN.*false will match everything up to the very last false on the line. You may have to resort to a perl-based solution where greedyness can be turned off. — AdminBee
– AdminBee, Commented Feb 7, 2020 at 8:29
Is there any way you can specify how the next such expression on the line starts. In your example, it was always colorX. Can we rely on a fixed pattern for the next word after the false you want to turn into true? — AdminBee
– AdminBee, Commented Feb 7, 2020 at 8:31
@Amelia Please edit your question and all all requested information there instead of answering in comments. My suggestion is to split the line at PATTERN, substitute the first false in the second part and combine the parts. Are you sure that the first false after PATTERN belongs to PATTERN? Or in other words: Are you sure that the value that belongs to PATTERN is always false and not true? What about a line colorA is false colorB is false PATTERN is true colorC is false colorD is false? — Bodo
– Bodo, Commented Feb 7, 2020 at 8:42

icarus · Accepted Answer · 2020-02-07 08:42:49Z

1

Whilst in theory it is possible to write a regular expression which matches the shortest string which doesn't match "false", it is hard. Various other languages have a syntax to choose shortest, but awk is not one of them.

So there are 3 approaches that can be used, assuming that you don't want to write the hard expression.

You can split the input on the word "false", loop over the fields, if the current field matches the pattern then print it out followed by "true", otherwise print it out followed by "false".
You can use a trick, convert all occurrences of "false" into a single unused character like control-a, then the regular expression is easy to write as you can say [^\001]*\001 to match the shortest pattern ending in control-a.
You just loop over the fields, if the current field is your pattern you set a flag, if it is "false" and the flag is set you change it to "true" and reset the flag.

For approach number 3.

#!/usr/bin/awk

/PATTERN.*false/ {
        for(i=1;i<=NF;i++) {
                if ($i ~ /PATTERN/) flag=1;
                if ($i == "false" && flag==1) {
                        $i="true"
                        flag=0
                }
        }
}
{print}

This will collapse the whitespace in the input.

answered Feb 7, 2020 at 8:42

icarus

19.1k1 gold badge42 silver badges57 bronze badges

Thanks icarus! We appreciate your attention.

Amelia
– Amelia

2020-02-07 09:00:25 +00:00
Commented Feb 7, 2020 at 9:00
@AdminBee I am sure my program answers the question as currently written, which is to change the first "false" after PATTERN to "true". The OP said there will be an unknown number of words after PATTERN, and there is no restriction on none of these words being "true". If this is a problem then adding if ($i == "true") flag=0; will fix it.

icarus
– icarus

2020-02-07 09:04:03 +00:00
Commented Feb 7, 2020 at 9:04
Yes, I think you are right. Error on my side!

AdminBee
– AdminBee

2020-02-07 09:11:23 +00:00
Commented Feb 7, 2020 at 9:11

Add a comment |

Bodo · Accepted Answer · 2020-02-07 11:22:25Z

This solution implements the approach to split the line at PATTERN (split), substitute the first false in the second part (sub) and combine the parts (for loop and printf). The next command skips further processing of this input line. Other lines are printed unchanged. (1 is an always true condition with default action.)

awk '/PATTERN.*false/ {
    n=split($0,parts,"PATTERN"); 
    sub("false", "true", parts[2]); 
    for(i=1;i<n;i++) {
        printf("%s%s", parts[i], "PATTERN");
    }
    printf("%s\n", parts[n]);
    next }
1'

It is unclear from the question if the value that corresponds to PATTERN is always false, so it may replace a wrong false.

Sample input

colorA is false colorB is false PATTERN is false colorC is false colorD is false
colorA is false colorB is false PATTERN is true colorC is false colorD is false

results in this output

colorA is false colorB is false PATTERN is true colorC is false colorD is false
colorA is false colorB is false PATTERN is true colorC is true colorD is false

Edit according to RudiC's comment: If the to-be-modified value after PATTERN is either "true" or "false", then this possible problem can be avoided by replacing the instruction sub("false", "true", parts[2]); with sub("false|true", "true", parts[2]);

awk '/PATTERN.*false/ {
    n=split($0,parts,"PATTERN"); 
    sub("false|true", "true", parts[2]); 
    for(i=1;i<n;i++) {
        printf("%s%s", parts[i], "PATTERN");
    }
    printf("%s\n", parts[n]);
    next }
1'

With the same sample input this results in

colorA is false colorB is false PATTERN is true colorC is false colorD is false
colorA is false colorB is false PATTERN is true colorC is false colorD is false

If the to-be-modified value after PATTERN is either "true" or "false", then sub (/true|false/, "true", parts[2] will get the deal done correctly. — RudiC
– RudiC, Commented Feb 7, 2020 at 9:26

Ed Morton · Accepted Answer · 2020-02-07 22:52:55Z

0

With GNU awk for the 3rd arg to match() and gensub():

$ awk 'match($0,/(.*PATTERN)(.*)/,a){$0=a[1] gensub(/false/,"true",1,a[2])} 1' file
...
colorA is false colorB is false PATTERN is true colorC is false colorD is false
...

and with any awk:

$ awk 'match($0,/.*PATTERN/){tail=substr($0,RSTART+RLENGTH); sub(/false/,"true",tail); $0=substr($0,1,RSTART+RLENGTH-1) tail } 1' file
...
colorA is false colorB is false PATTERN is true colorC is false colorD is false
...

answered Feb 7, 2020 at 22:52

Ed Morton

36k6 gold badges25 silver badges60 bronze badges

Add a comment |

Stack Exchange Network

awk -- replace once after immediate pattern in same line!

3 Answers 3

You must log in to answer this question.

Hot Network Questions

awk -- replace once after immediate pattern in same line!

3 Answers 3

You must log in to answer this question.

Related

Hot Network Questions