CoffeeScript instance variable

Question

I'm learning CoffeeScript, and I've got one minor headache I haven't quite been able to figure out. If I create an object to do certain things, I occasionally need an instance variable for that object to be shared between methods. For instance, I'd like to do this:

testObject = 

  var message # <- Doesn't work in CoffeeScript.

  methodOne: ->
    message = "Foo!"

  methodTwo: ->
    alert message

However, you can't use var in CoffeeScript, and without that declaration message is only visible inside methodOne. So, how do you create an instance variable in an object in CoffeeScript?

Update: Fixed typo in my example so the methods are actually methods :)

BTW I'm aware that I could do message = "", but I really just want the variable to be null so I can set behavior based on existence rather than a more complex check to see if it's not "blank" etc. — Andrew
– Andrew, Commented Apr 12, 2012 at 21:25
You can also set message = null which is what you want no? — Sandro
– Sandro, Commented Apr 12, 2012 at 21:34
When I try message = null I get ParseError Unexpected 'TERMINATOR' — Andrew
– Andrew, Commented Apr 12, 2012 at 21:41
Oh yea, like the correct answer mentioned, you were assigning testObject to an object = and not a function = ()-> — Sandro
– Sandro, Commented Apr 12, 2012 at 22:02

Lauren · Accepted Answer · 2012-04-12 21:38:00Z

You can't like that. To quote the language reference:

Because you don't have direct access to the var keyword, it's impossible to shadow an outer variable on purpose, you may only refer to it. So be careful that you're not reusing the name of an external variable accidentally, if you're writing a deeply nested function.

However what you're trying to do wouldn't be possible in JS either, it would be equivalent to

testObject = {
    var message;
    methodOne: message = "Foo!",
    methodTwo: alert(message)
}

which isn't valid JS, as you can't declare a variable in an object like that; you need to use functions to define methods. For example in CoffeeScript:

testObject =
    message: ''
    methodOne: ->
        this.message = "Foo!"
    methodTwo: ->
        alert message

You can also use @ as a shortcut for 'this.', i.e. @message instead of this.message.

Alternatively consider using CoffeeScript's class syntax:

class testObject
    constructor: ->
        @message = ''

    methodOne: ->
        @message = "Foo!"

    methodTwo: ->
        alert @message

Ricardo Tomasi · Accepted Answer · 2012-06-21 07:38:01Z

5

Just to add to @Lauren's answer, what you wanted is basically the module pattern:

testObject = do ->

  message = null

  methodOne = ->
    message = "Foo!"

  methodTwo = ->
    alert message

  return {
    methodOne
    methodTwo
  }

Where message is a "private" variable only available to those methods.

Depending on the context you could also declare message before the object so that it's available to both methods (if executed in this context):

message = null

testObject = 
  methodOne: -> message = "Foo!"
  methodTwo: -> alert message

edited Jun 21, 2012 at 7:38

answered Apr 13, 2012 at 0:09

Ricardo Tomasi

35.3k2 gold badges58 silver badges66 bronze badges

2 Comments

Julian D. Over a year ago

Correct, but your code is a bit buggy: do will simply create a closure, you therefore cannot define properties but should use vars instead (methodOne = ->... etc.) Also, the return statement should probably be {methodOne:methodOne, methodTwo:methodTwo}. Of course you could put your method definitions right into the return statement instead...

Ricardo Tomasi Over a year ago

@JulianD. copy&pasta :) The return statement is using destructuring assignment.

Jonathan Lonowski · Accepted Answer · 2012-04-12 21:41:34Z

1

You can define the property with:

message: null

~~But, you aren't currently defining methods -- you need -> for that.~~

Then, to refer to instance properties within the methods, prefix the property names with @.

testObject = 

  message: null

  methodOne: ->
    @message = "Foo!"

  methodTwo: ->
    alert @message

edited Apr 12, 2012 at 21:41

answered Apr 12, 2012 at 21:29

Jonathan Lonowski

124k35 gold badges203 silver badges202 bronze badges

4 Comments

Kristoffer Sall-Storgaard Over a year ago

-> is not required: see my fixed version

Lauren Over a year ago

@KristofferSHansen your version isn't fixed; as you can see by pressing 'Run' on that page, it would show an alert dialog immediately, and that is probably not what Andrew is after, more likely he wants to defer its execution until that method is called.

Jonathan Lonowski Over a year ago

@KristofferSHansen It is for function/methods. Without it, methodTwo is set to the result of calling alert, not a function that in turn calls alert.

Andrew Over a year ago

Thanks for catching the typo, I fixed it. My real code had the ->.

Kristoffer Sall-Storgaard · Accepted Answer · 2012-04-12 21:32:44Z

0

Use @ to point to this

testObject = 

  methodOne: ->
    @message = "Foo!"

  methodTwo: ->
    alert @message

fixed version on coffeescript.org

answered Apr 12, 2012 at 21:32

Kristoffer Sall-Storgaard

10.7k5 gold badges39 silver badges46 bronze badges

Collectives™ on Stack Overflow

CoffeeScript instance variable

4 Answers 4

Comments

2 Comments

4 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

2 Comments

4 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related