XSLT for XML containing multiple namespaces

Question

I'm working on an XSLT that is giving me a little headache, and was looking for some tips. I'm working on converting an XML where some of the tags have namespaces prefixes, and others do not. I am working to convert all of the tags to one common namespace prefix.

Example of XML:

<yes:Books>
   <no:Book>
      <Title>Yes</Title>
      <maybe:Version>1</maybe:Version>
   </no:Book>
</yes:Books>

What I'm trying to get:

<yes:Books>
   <yes:Book>
      <yes:Title>Yes</yes:Title>
      <yes:Version>1</yes:Version>
   </yes:Book>
</yes:Books>

The XML input is the aggregate of several webservices, that are returning various namespaces. I have no issue aggregating it together appropriately, it's creating one common prefix namespace that I am having an issue with.

Worst case, I could regex them away, but I'm sure that isn't recomended.

Thanks.

Dimitre Novatchev · Accepted Answer · 2012-04-20 04:11:22Z

This transformation allows the wanted final prefix and its namespace to be specified as external/global parameters. It shows how to process in the same way attribute names:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pPrefix" select="'yes'"/>
 <xsl:param name="pNamespace" select="'yes'"/>

 <xsl:template match="*">
  <xsl:element name="{$pPrefix}:{local-name()}" namespace="{$pNamespace}">
   <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="@*">
  <xsl:attribute name="{$pPrefix}:{local-name()}" namespace="{$pNamespace}">
   <xsl:value-of select="."/>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

when applied on the following document (the provided one with one added attribute to make the problem more challenging):

<yes:Books xmlns:yes="yes">
    <no:Book xmlns:no="no">
        <Title no:Major="true">Yes</Title>
        <maybe:Version xmlns:maybe="maybe">1</maybe:Version>
    </no:Book>
</yes:Books>

produces the wanted, correct result:

<yes:Books xmlns:yes="yes">
   <yes:Book>
      <yes:Title yes:Major="true">Yes</yes:Title>
      <yes:Version>1</yes:Version>
   </yes:Book>
</yes:Books>

Ben · Accepted Answer · 2012-04-20 03:31:20Z

0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:custom="c">
    <xsl:template match="/">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="*">
        <xsl:element name="custom:{local-name()}" namespace-uri="c">
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

edited Apr 20, 2012 at 3:31

Ben

13.7k4 gold badges51 silver badges70 bronze badges

answered Apr 20, 2012 at 3:20

alanstroop

1562 bronze badges

1 Comment

Dimitre Novatchev Over a year ago

This transformation has a problem in the general case. Attributes are deleted.

Collectives™ on Stack Overflow

XSLT for XML containing multiple namespaces

2 Answers 2

Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related