How to replace one or more strings within a string in Perl

Question

$args[0] is a reference to a string containing one or more times. I am shifting each time by a variable number of seconds, but then I need to find a way to store (replace) the changed times back into the original string. Any help is appreciated. Here is roughly what I am working with:

    my $TIMEREGEX = qr/(\d{2}:\d{2}:\d{2}\.\d{3}|\d{2}:\d{2}:\d{2})/x;
    if ( my @sTime = ${$args[0]} =~ /$TIMEREGEX/g )
    {
        warn "\ttime(s) found @sTime\n" if $main::opt{d};
        for my $i ( 0..$#sTime )
        {
            $sTime[$i] =~ /(\d{2}):(\d{2}):(\d{2})(\.(\d{3}))?/;
            my $epoch_time = ( $1 * 3600 ) + ( $2 * 60 ) + $3;
            $epoch_time += $epoch_shift;
            my @f;
            $f[0] = $epoch_time % 86400 / 3600; # hours
            $f[1] = $epoch_time % 3600 / 60;    # minutes
            $f[2] = $epoch_time % 60;           # seconds
            my $save = $sTime[$i];
            $sTime[$i] = sprintf ( "%02d:%02d:%02d", $f[0], $f[1], $f[2] );
            $sTime[$i] .= $4 if defined ( $4 );
            warn "\tTimeShift $save => $sTime[$i]\n" if $main::opt{d};
            ### some other stuff
        }

        # ${$args[0]} = "$1$t[0]$4$t[1]$7$t[2]$10";
        ### save the changes to ${$args[0]} !

    }

maybe you looking for s///? and also use s///e with e-key. — gaussblurinc
– gaussblurinc, Commented Apr 23, 2012 at 10:57
or look to split function and join function. they will make your work more simple ;) — gaussblurinc
– gaussblurinc, Commented Apr 23, 2012 at 10:58
Why not use a module that can handle time for you? Like DateTime or Time::Piece. — TLP
– TLP, Commented Apr 23, 2012 at 10:59

daxim · Accepted Answer · 2012-04-23 11:31:06Z

2

Use the substitution operator.

use 5.010;  # or better for 'say' and '//'
use strictures;
use Time::Piece qw();

my @args; my $epoch_shift = 500;
${$args[0]} = 'foo18:00:00.123bar18:00:00baz18:00:00quux';

${$args[0]} =~
    s{
        (\d{2}:\d{2}:\d{2})  # capture hh:mm:ss
        (\.\d{3})?           # optionally capture
                             #   decimal dot and milliseconds
    }
    {
        (
            $epoch_shift
            + Time::Piece->strptime($1, '%T')
        )->strftime('%T').($2 // '')
    }egx;
say ${$args[0]};
# foo18:08:20.123bar18:08:20baz18:08:20quux

edited Apr 23, 2012 at 11:31

answered Apr 23, 2012 at 11:09

daxim

39.3k4 gold badges71 silver badges135 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

harmonic Over a year ago

thanks! didn't occur to me to use an expression inside a substitution

Collectives™ on Stack Overflow

How to replace one or more strings within a string in Perl

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related