XSLT

Question

I am trying to generate an XML output and i have created an XSLT that will do so. However the root node is is missing some Name spacing. How do you add Namespace to the root element of an XML structure. This it the XSLT i am using:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
    xmlns:doc="urn:sapcom:document:sap:rfc:functions" xmlns:r="http://www.castiron.com/response" exclude-result-prefixes="r">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/">
        <xsl:element name="imageScene7Request">
            <xsl:element name="productIds">
                <xsl:for-each select="r:productGetAllByIdsResponse/r:payload/r:products">
                    <xsl:value-of select="r:id"/>
                    <xsl:if test="position() != last()">
                        <xsl:text>,</xsl:text>
                    </xsl:if>
                </xsl:for-each>
            </xsl:element>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

The Namespacing i would like to add to the root http://www.castiron.com/response

INPUT XML

<?xml version="1.0" encoding="UTF-8"?>
<productGetAllByIdsResponse xmlns="http://www.castiron.com/response">
    <rcode>0</rcode>
    <rmessage>Success</rmessage>
    <payload>
        <products>
            <id>4022280</id>
        </products>
        <products>
            <id>4022280</id>
        </products>
    </payload>
</productGetAllByIdsResponse>

You will see that when you run this is gives you:

<?xml version="1.0" encoding="utf-8"?>
<imageScene7Request>
    <productIds>4022280,4022280</productIds>
</imageScene7Request>

However i would like this:

<?xml version="1.0" encoding="utf-8"?>
<imageScene7Request xmlns="http://www.castiron.com/response">
    <productIds>4022280,4022280</productIds>
</imageScene7Request>

Reply @dbaseman

That worked however it then gave the second tag a null namespace, as shown below:

<?xml version="1.0" encoding="utf-8"?>
<imageScene7Request xmlns="http://www.castiron.com/response">
    <productIds xmlns="">4022280,4022280</productIds>
</imageScene7Request>

Is there a way to remove that?

Michael Kay · Accepted Answer · 2012-05-30 13:10:46Z

4

Since you know statically what the names of your result elements are, it's much better to use literal result elements rather than xsl:element:

 <xsl:template match="/">
    <imageScene7Request xmlns="http://www.castiron.com/response">
        <productIds>
            <xsl:for-each select="r:productGetAllByIdsResponse/r:payload/r:products">
                <xsl:value-of select="r:id"/>
                <xsl:if test="position() != last()">
                    <xsl:text>,</xsl:text>
                </xsl:if>
            </xsl:for-each>
        </productIds>
    </imageScene7Request>
</xsl:template>

If you do use xsl:element you need to be sure to use the namespace attribute to make sure the element is in the right namespace.

answered May 30, 2012 at 13:10

Michael Kay

165k11 gold badges97 silver badges173 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

McGarnagle · Accepted Answer · 2012-05-30 09:10:17Z

3

I think you just need to specify the namespace explicitly in the stylesheet:

<xsl:element name="imageScene7Request" namespace="http://www.castiron.com/response">
    <xsl:element name="productIds">
       ...
    </xsl:element>
</xsl:element>

answered May 30, 2012 at 9:10

McGarnagle

103k31 gold badges235 silver badges264 bronze badges

1 Comment

mmkd Over a year ago

I have added a comment to the bottom of my post. Thank you for your help.

Eric · Accepted Answer · 2012-05-30 13:24:39Z

1

Does this work?

<xsl:stylesheet xmlns="http://www.castiron.com/response" ...>

That will set the namespace of all elements within the XSLT to http://www.castiron.com/response

answered May 30, 2012 at 13:24

Eric

98.1k54 gold badges257 silver badges389 bronze badges

Collectives™ on Stack Overflow

XSLT - Add Namespace to Output

XSLT

INPUT XML

Reply @dbaseman

3 Answers 3

Comments

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

XSLT

INPUT XML

Reply @dbaseman

3 Answers 3

Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related