Converting a sequence of maps into a multimap

Question

I have a sequence of maps.

;; input
[{:country "MX", :video 12345, :customer "cid1"}
 {:country "US", :video 12345, :customer "cid2"}
 {:country "MX", :video 54321, :customer "cid1"}]

I want to convert it into a multimap. I want to generate.

;; output
{"cid1"
     {:actions
          [{:country "MX", :video 12345, :customer "cid1"}
           {:country "MX", :video 12345, :customer "cid1"}]},
 "cid2" 
     {:actions
          [{:country "US", :video 12345, :customer "cid2"}]}}

I feel like I should be using update-in. Something along the lines of... I just have not worked out exactly what some-fn-here looks like and I figured that others may have the same question.

(defn add-mm-entry
    [m e]
    (update-in m [(:customer e)] some-fn-here))

(def output (reduce add-mm-entry {} input))

Figured I'd throw it out to the community while I work on it. If I'm going down the wrong path here let me know.

Eric Schoonover · Accepted Answer · 2012-06-27 05:51:52Z

5

If I understand the intent correctly, you are grouping by :customer and then wrapping the vector of actions into :actions. You can do the grouping with clojure.core/group-by and then map (clojure.core/map) the result:

(def v [{:country "MX", :video 12345, :customer "cid1"}
        {:country "US", :video 12345, :customer "cid2"}
        {:country "MX", :video 54321, :customer "cid1"}])

(->> v
     (group-by :customer)
     (map (fn [[cid xs]] {cid {:actions xs}}))
     (into {}))

edited Jun 27, 2012 at 5:51

Eric Schoonover

48.6k50 gold badges161 silver badges203 bronze badges

answered Jun 27, 2012 at 4:55

Michael Klishin

7963 silver badges6 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Dave Ray Over a year ago

The final output should be a map, so you need to run the result through (into {}).

Eric Schoonover · Accepted Answer · 2012-06-27 05:57:34Z

Michael's answer works well. I'm not sure if group-by will work well for my specific case because of the size of the data that I am loading. I have not tested it but I think this approach will lead to less intermediate product.

(def v [{:country "MX", :video 12345, :customer "cid1"}
        {:country "US", :video 12345, :customer "cid2"}
        {:country "MX", :video 54321, :customer "cid1"}])

(defn add-entry
    [m e]
    (let [cust (:customer e)]
        (update-in m [cust :actions] #(conj % e))))

(reduce add-entry {} v)

Still results in full data set being loaded, but it is directly loaded into the target data structure instead of into a vector of maps and then into a multimap. Again, I have not tested to check which one is definitively more performant, but it looks like this one has one less iteration over the data set and avoids creating the unwanted vector of maps that comes out of group-by.

Collectives™ on Stack Overflow

Converting a sequence of maps into a multimap

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related