Finding multiple substrings in a single string using Perl

Question

I need to take the following string and break it into chunks:

[ToNode=cup-subscriber][Reason=Critical service is down][FromNode=cup-publisher][AppID=Cisco UP Server Recovery Manager]

Each chunk is encapsulated in brackets. I'm looking to do this in Perl, and am looking for direction on a method.

Thanks!

@chunks = split /(?:\]|^)(?:\[|$)/, $string for a rather quick and dirty solution. — amon
– amon, Commented Sep 26, 2012 at 13:54

pmakholm · Accepted Answer · 2012-09-26 13:57:31Z

5

Use the /g modifier for regular expressions. Either in list context to extract into an array:

$data = "[ToNode=cup-subscriber][Reason=Critical service is down][FromNode=cup-publisher][AppID=Cisco UP Server Recovery Manager]"
my @chunk = ( $data =~ /\[(.*?)\]/g );

or in a while loop to iterate over the chunks:

$data = "[ToNode=cup-subscriber][Reason=Critical service is down][FromNode=cup-publisher][AppID=Cisco UP Server Recovery Manager]"
while ( $data =~ /\[(.*?)\]/g ) {
    process($1);
}

answered Sep 26, 2012 at 13:57

pmakholm

1,5788 silver badges24 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

codaddict · Accepted Answer · 2012-09-26 13:59:27Z

2

You can split at the point between ] and a [ using lookahead and lookbehind assertions:

$str = '[ToNode=cup-subscriber][Reason=Critical service is down]
        [FromNode=cup-publisher][AppID=Cisco UP Server Recovery Manager]';

@pieces = split/(?<=\])(?=\[)/,$str;

See it

answered Sep 26, 2012 at 13:59

codaddict

457k83 gold badges501 silver badges537 bronze badges

1 Comment

Dan Bough Over a year ago

This is the one I used. Thank you!

mscha · Accepted Answer · 2012-09-26 14:51:36Z

Try this:

my $str = '[ToNode=cup-subscriber][Reason=Critical service is down][FromNode=cup-publisher][AppID=Cisco UP Server Recovery Manager]';
my %fields = $str =~ m{\[([^][=]+)=([^][=]+)\]}g;
say "$_: $fields{$_}" for sort keys %fields;

Or more verbosely:

my $str = '[ToNode=cup-subscriber][Reason=Critical service is down][FromNode=cup-publisher][AppID=Cisco UP Server Recovery Manager]';

# Capture all occurrences of ...
my %fields = $str =~ m{
            \[              # Open bracket
            ( [^][=]+ )     # Sequence of 1 or more non ][= characters
            =               # Equals
            ( [^][=]+ )     # Sequence of 1 or more non ][= characters
            \]              # Close bracket
        }xg;

# Dump contents of %fields
say "$_: $fields{$_}" for sort keys %fields;

Collectives™ on Stack Overflow

Finding multiple substrings in a single string using Perl

3 Answers 3

Comments

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related