Assign address of one array to another in Perl possible?

Question

In the following C# code:

int[] X = new int[2];
X[0] = 1;
X[1] = 2;
int[] Y = X;
X[1] = 3;

After this executes, Y[1] will also be 3 since the operation Y = X does not do a clone but rather assigns the reference or pointer of what X is pointing at to Y.

If the same operation is tried under Perl 5:

my @X = (1, 2);
my @Y = @X;
$X[1] = 3;

Unlike C#, Y[1] is not 3, but still 2, which indicates that Perl makes a copy of the array after the @Y = @X operation.

So, my question is - is there any way to assign or initialize a Perl 5 array with the reference of another Perl array so that they both point to the same data? I already know about references and have tried dereferencing a reference to an array, but that too makes a copy. I'm also aware that using a reference to an array will solve most of what I'm trying to do, so I don't need any answers showing how to work with references.

ikegami · Accepted Answer · 2012-10-18 16:55:20Z

4

You're using a reference in the C# program, but not in the Perl program. It works the same if you use a reference in Perl.

my $X = [ 1, 2 ];
my $Y = $X;
$X->[1] = 3;
print "@$Y\n";  # 1 3

or

my @X = ( 1, 2 );
my $Y = \@X;
$X[1] = 3;
print "@$Y\n";  # 1 3

You could also create an alias.

use Data::Alias qw( alias );

my @X = ( 1, 2 );
alias my @Y = @X;
$X[1] = 3;
print "@Y\n";  # 1 3

edited Oct 18, 2012 at 16:55

answered Oct 18, 2012 at 16:14

ikegami

391k17 gold badges291 silver badges555 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Bob Bryan Over a year ago

If a complex data structure is being used - for example an array of hashtables containing arrays as values. Can alias be used to acquire each one of those individual structures, including an array used within a hashtable value? In other languages, this can be easily done. If this can not be easily done in Perl, then it implies that complex data structures should use references instead. So for example, the above data structure could be defined to be an array of hash references containing values of references to arrays.

ikegami Over a year ago

@Bob Bryan, You can't have arrays as values of a hash. Hash values can only be scalars, such as references to arrays.

Bob Bryan Over a year ago

I am still new to Perl, so I could be wrong about this. But, according to Programming Perl, 4th edition in chapter 9: Data Structrues on page 374 under Hashes of Arrays topic shows several examples on how to add arrays to a hash: %Hoa (flinstones => ["fred", "barney"], jetsons => ["george", "jane", "elroy"], simpsons => ["homer", "marge", "bart"], ); If this code is not creating a hash of arrays, then can you please explain what it is doing.

ikegami Over a year ago

"hash of arrays" is short for "hash of references to arrays". What you have there is the same as

my @anon1 = ("fred", "barney"); my @anon2 = ("george", "jane", "elroy"); my @anon3 = ("homer", "marge", "bart"); %Hoa = (flinstones => \@anon1, jetsons => \@anon2, simpsons => \@anon3);

You're working with references. There's no reason to introduce aliases.

TLP · Accepted Answer · 2012-10-18 16:18:09Z

2

The way to create a reference to a specific named variable is by using backslash like so:

my @x = (1,2);
my $y = \@x;            # create reference by escaping the sigil

$y->[1] = 3;            # $x[1] is now 3
for ( @$y ) { print }   # how to reference the list of elements

You may also create a reference by using an anonymous array:

my $x = [1,2];          # square brackets create array reference
my $y = $x;             # points to the same memory address

The reference is a scalar value, so it would be $y in your case. If you put an array reference into an array, you get a two-dimensional array, which is handy to know for future reference. E.g.:

my @two = (\@x, \@y);                 # $two[0][0] is now $x[0]
my @three = ( [1,2], [3,4], [4,5] );  # using anonymous arrays

edited Oct 18, 2012 at 16:18

answered Oct 18, 2012 at 16:10

TLP

68.2k10 gold badges97 silver badges156 bronze badges

Comments

Matteo · Accepted Answer · 2012-10-18 16:13:16Z

1

In Perl an array is not a pointer.

You can get the reference of an array with the \ operator:

my @array = ( 1, 2 );
my $array_ref = \@array;

$array_ref will then point to the original array (as in C)

${$array_ref}[0] = 3

will change the first cell of the original array (i.e., $array[0] will be 3)

answered Oct 18, 2012 at 16:13

Matteo

15k11 gold badges70 silver badges109 bronze badges

Comments

Gilles Quénot · Accepted Answer · 2012-10-18 16:17:39Z

1

Try doing this :

my @X = (1, 2);
my $ref = \@X;        # $ref in now a reference to @X array (the magic is `\`)
$ref->[0] = "foobar"; # assigning "foobar" to the first key of the array
print join "\n", @X;  # we print the whole @X array and we see that it was changed

edited Oct 18, 2012 at 16:17

answered Oct 18, 2012 at 16:10

Gilles Quénot

188k43 gold badges232 silver badges229 bronze badges

Collectives™ on Stack Overflow

Assign address of one array to another in Perl possible?

4 Answers 4

4 Comments

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

4 Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related