If else function in .bat script + findstr command

Question

IF find tcp.client == 1 

(


 findstr tcp.client *_chkpackage.log>summary.txt 
) 

ELSE 
(

#write only "filename" & "N/A" >> summary.txt

)

i want to search a file that search some value in all text files in folder if found the line that contain information i need it is going to write that line to text fiel if not found the it will write only filename and "N/A" to the line

i know it wrong but my coding skill suck so i have to ask

thank you so much for the answer

pbhd · Accepted Answer · 2012-12-03 11:08:22Z

4

Something that works according to your "specification" would be that one:

@echo off
if exist summary.txt del summary.txt
for %%f in (*_chkpackage.log) do (
  find "tcp.client" %%f>NUL:
  IF errorlevel 1 (
    echo %%f N/A >> summary.txt
  ) ELSE (
    findstr "tcp.client" %%f >> summary.txt
  )
)
type summary.txt

Note that the if errorlevel 1 means "if errorlevel is greater or equal 1", for that I swapped your comparison, because if errorlevel 0 is true even when errorlevel equals 1.

answered Dec 3, 2012 at 11:08

pbhd

4,4671 gold badge23 silver badges26 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

dbenham Over a year ago

Your success output is missing the filename prefix. Also, FINDSTR sets its own errorlevel, so no need for the extra FIND step.

pbhd Over a year ago

Hmm. In the success case there was no filename-prefix requested. So the extra find was intruduced to handle these different cases of output :-)

dbenham Over a year ago

It was not explicitly requested, but the OP code uses FINDSTR with a wild card in the filespec, which results in the file name being prefixed to each matching line. I'm quite sure the OP would like to keep that functionality. You removed the wildcard, which removes the name prefix from the output.

dbenham Over a year ago

Look at my answer for a concise way to sove the problem :)

dbenham · Accepted Answer · 2012-12-03 13:06:28Z

2

I'm assuming the dot is a dot and not a regex wildcard, in which case you need to tell FINDSTR to do a literal search.

FINDSTR returns success if found, error if not found. The || operator conditionally executes commands if the prior command failed.

Use FOR loop to get each file individually, and add an additional file (nul) that will never match to force inclusion of file name in output.

Enclose entire construct in parentheses and redirect the entire block

@echo off
>summary.txt (
  for %%F in (*_chkpackage.log) do findstr /l "tcp.client" "%%F" nul||echo %%F N/A
)

answered Dec 3, 2012 at 13:06

dbenham

132k29 gold badges273 silver badges410 bronze badges

2 Comments

dbenham Over a year ago

@eathapeking - If you get a good post that fully answers your question and meets your needs then you should accept it by clicking on the check mark near the upper left corner. That action lets others know the question has been answered, it awards you 2 rep points, and awards the answer poster 15 points. Only one answer can be accepted per question. Once you reach 15 rep points you gain the privilege to up vote any answer you find useful, including answers to other people's questions. An up vote awards 10 points to the answer poster.

eathapeking Over a year ago

yep i did it :) but why it have to be only 1 check for the best answer T^T everyone should get mark for answer

Collectives™ on Stack Overflow

If else function in .bat script + findstr command

2 Answers 2

4 Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

4 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related