Using variables in multiple places - AS3

Question

How do I add Variable "userSave" so the code looks like the second snippet?

var userSave:Number = 1;

user_presets["u"+userSave].addEventListener(MouseEvent.MOUSE_DOWN, ["u"+userSave]);
function ["u"+userSave](event:MouseEvent):void
{

}


// It needs to look like this:
user_presets.u1.addEventListener(MouseEvent.MOUSE_DOWN, u1);
function u1(event:MouseEvent):void
{

}

EDIT: OK, Let me try to explain exactly what I am trying to achieve. I apologize for being so vaque. It's taken me some time to figure out what I am going for.

I have 36 buttons that I want to do the code below. The code below is the first button. The next buttons need to be u2, u3, u4, etc. So all instances of u1 in the following code need to be changed accordingly for each button. How do I do this without duplicating this code 36 times? Code is on the timeline.

f_presets.user_presets.u1.addEventListener(MouseEvent.MOUSE_DOWN, u1);

function u1(event:MouseEvent):void
{

if (saveFlag == "play")
{

userSave = "u1";
myuserSave();


}
else
{
    userSave = "u1";
myuserPlay();

}

}

Final EDIT Thanks for all the help. This is what ended up working for me.

for (var i:Number=1; i<37; i++)
{
var userSaver = "u" + i;
f_presets.user_presets[userSaver].addEventListener(MouseEvent.MOUSE_DOWN, recall);
function recall(event:MouseEvent):void
{
    if (saveFlag == "play")
    {
        trace(userSave = event.currentTarget.name);
        myuserSave();
    }
    else
    {
        trace(userSave = event.currentTarget.name);
        if (mySO.data["user_saved" + userSave] == "yes")
        {
            myuserPlay();
        }
    }
}
}

Not sure exactly what you are trying to achieve. Are you trying to add an eventListener to multiple buttons ? — prototypical
– prototypical, Commented Dec 15, 2012 at 1:57
Magic number for the amount of buttons and concatenating strings to build a username is a bit sloppy. It'll work, but if you chose my route of containing all the buttons in a single display object and then iterating through would require no code changes if you ever changed the amount of buttons. -- if your buttons are all exclusively contained in the same display object, the code would work as noted. — prototypical
– prototypical, Commented Dec 17, 2012 at 3:32
Also, in the final code, your event handler function is encapsulated in the loop. — prototypical
– prototypical, Commented Dec 17, 2012 at 3:34
Thanks for pointing out the encapsulated handler. I will look again to get your code working. I tried for hours and it would not work. I guess I just don't understand. I will try again. — akhunaton
– akhunaton, Commented Dec 17, 2012 at 8:23

user1901867 · Accepted Answer · 2012-12-15 01:39:04Z

1

Not sure if i understand what you are trying to achieve but assuming userSave would take multiple values...

//save userSave for later
user_presets["u"+userSave].id = String(userSave);
//add listener
user_presets["u"+userSave].addEventListener(MouseEvent.MOUSE_DOWN, eventHandler);

function eventHandler(event:MouseEvent):void
{
    //retrieve userSave from target
    var userSaveValue:Number = Number(event.target.id);
    //do something based on value of userSave...?    
}

Or maybe use an inline function (definitely not best practice, but needs must sometimes):

user_presets["u"+userSave].addEventListener(MouseEvent.MOUSE_DOWN, function(event:MouseEvent){
    //code here
});

answered Dec 15, 2012 at 1:39

user1901867

Sign up to request clarification or add additional context in comments.

1 Comment

akhunaton Over a year ago

Thanks for taking the time to answer my question. I have updated my original question based on all the answers I have received. I now know exactly what I am trying to achieve. Do you mind looking at it again? thanks.

prototypical · Accepted Answer · 2012-12-16 20:00:59Z

1

You need to adjust your approach to make this simplistic.

First I am assuming that the children of save_presets are all your buttons. If not, you should consider having a container for JUST those buttons so you can simply do this :

for(var index:int = 0;index < save_presets.numChildren;index++)
{
    var button:MovieClip = save_presets.getChildAt(index) as MovieClip;
    button.id = index;
    button.addEventListener(MouseEvent.MOUSE_DOWN, eventHandler);
}

To remove the handlers you could just do this :

for(var index:int = 0;index < save_presets.numChildren;index++)
{
    var button:MovieClip = save_presets.getChildAt(index) as MovieClip;
    button.removeEventListener(MouseEvent.MOUSE_DOWN, eventHandler);
}

edited Dec 16, 2012 at 20:00

answered Dec 15, 2012 at 2:09

prototypical

6,7413 gold badges26 silver badges34 bronze badges

3 Comments

akhunaton Over a year ago

Thanks for taking the time to answer my question. I have updated my original question based on all the answers I have received. I now know exactly what I am trying to achieve. Do you mind looking at it again? thanks.

prototypical Over a year ago

Evaluate this approach, I changed my answer after getting a better understanding of you issue.

akhunaton Over a year ago

I studied your approach and used it to lead me to my solution. Thanks so much for the help.

Jonny Henly · Accepted Answer · 2012-12-16 18:37:55Z

EDIT:

Alrighty I'm pretty sure I know what you want to do and here is an example class. This class creates 36 square buttons with 1 pixel space between each button. Each button has an event listener and each fires an event when the mouse is down over the button. I hope this helps, if not let me know

package {

import flash.display.MovieClip;
import flash.events.*;
import flash.geom.*; // Used to create rectangle for buttons

/**
 * ...
 * @author [Your Name Here]
 */
public class Main extends MovieClip
{
    public var user_presets:Array; // Array to store buttons

    public const BUTTON_COUNT:int = 36; // How many buttons do you want?

    public function Main():void 
    {   
        user_presets = new Array(); // Initialize button array

        this.addEventListener(Event.ADDED_TO_STAGE, onAddedToStage); // Listener for ADDED_TO_STAGE event
    }

    private function onAddedToStage(e:Event = null):void 
    {
        var tmpX:int = 0; // Button's x value
        var tmpY:int = 0; // Button's y value

        for (var i:int = 0; i < BUTTON_COUNT; i++) { // For loop to create 36 buttons

            var tmpButton:MovieClip = new MovieClip(); // Create a temporary button

            tmpButton.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown); // Add MOUSE_DOWN event listener to the temporary button

            tmpButton.graphics.beginFill(0x000000, 1); // Fill the rectangle we create with 0x000000 (Black)
            tmpButton.graphics.drawRect(0, 0, 10, 10); // Draw a 10 x 10 rectangle that will be one button
            tmpButton.graphics.endFill(); // Stop filling rectangle

            tmpButton.name = "u" + (i + 1); // This is your u1, u2 ... u(n) where n is how many buttons you want
            tmpButton.x = tmpX; // Temporary buttons x value
            tmpButton.y = tmpY; // Temporary buttons y value

            tmpX += 11; // Add 11 to tmpButtons x value, basically adding a 1 pixel space between each button

            user_presets.push(tmpButton); // Add the temporary button to your user_presets array

            stage.addChild(tmpButton); // Add the temporary button to the stage

            } // Repeat above steps 35 times

        this.removeEventListener(Event.ADDED_TO_STAGE, onAddedToStage); // Remove the ADDED_TO_STAGE listener
    }

    public function onMouseDown(event:Event):void
    {
        trace(event.currentTarget.name); // Output which button was clicked

        // I used a switch statement but you can use if else statements if you'd like,
        // I think switch statements are easier to code for alot of conditionals.
        switch(event.currentTarget.name) {
            case "u1": // If the mouse is down over the first button, output "u1 was clicked!"
                trace("u1 was clicked!");
                break;

            case "u2": // If the mouse is down over the second button, output "u2 was clicked!"
                trace("u2 was clicked!");
                break;
        }
    }

}

}

Thanks for taking the time to answer my question. I have updated my original question based on all the answers I have received. I now know exactly what I am trying to achieve. Do you mind looking at it again? thanks.
Thanks again. Your answer was very helpful and I learned a lot from studying it. My final solution is posted in my EDIT.

Collectives™ on Stack Overflow

Using variables in multiple places - AS3

3 Answers 3

1 Comment

3 Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

3 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related