How do I replace a string variable within a string variable in my cmd batch file?

Question

I want to see if a string contains another string where both strings are variables. Basically it is that same as this thread but with two variables. Taking that solution and applying it to my situation with !VAR1! and !VAR2! (these variables are declared within the FOR loop) I tried:

if not x!VAR1:!VAR2!=!==x!VAR1! ECHO It contains !VAR2!

Unfortunately it doesn't work. Any help would be greatly appreciated. I have also declared SETLOCAL EnableDelayedExpansion so I can access the variables.

Any help would be greatly appreciated!

Thanks!

rojo · Accepted Answer · 2013-02-20 16:20:19Z

4

When I'm checking whether a string exists within another string, I like to use a for loop rather than if.

for /f "delims=" %%I in ('echo !VAR1! ^| findstr /i /c:"!VAR2!"') do (
    echo !VAR1! contains !VAR2!
)

This has the added benefit of case-insensitive matches.

If you prefer keeping the if statement, then try an intermediate variable to reduce confusion.

set vt=!VAR1:%VAR2%=!
if x%vt%==x%VAR1% (
    echo %VAR1% remained the same after removing %VAR2%.  %VAR1% did not contain %VAR2%
)

edited Feb 20, 2013 at 16:20

answered Feb 20, 2013 at 16:11

rojo

24.5k5 gold badges61 silver badges104 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

dbenham Over a year ago

Variable expansion search and replace is always case insensitive. FINDSTR gives you the option of case sensitive or insensitive search. I prefer the IF method if doing case insensitive search - it is much faster.

dbenham Over a year ago

No need for FOR /F when using FINDSTR. Also, your current FOR /F may print multiple times if !VAR1! contains linefeeds. If using FOR /F, then better to do it like Patrick's answer

Aacini · Accepted Answer · 2013-02-20 17:15:38Z

4

if "!VAR1:%VAR2%=!" neq "!VAR1!" echo It contains !VAR2!

answered Feb 20, 2013 at 17:15

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

1 Comment

rojo Over a year ago

+1 I didn't realize neq worked with strings as well. Cool.

dbenham · Accepted Answer · 2013-02-21 04:22:35Z

3

As Aacini and rojo have shown, you must use a different expansion for the two variables, normal inside, and delayed outside.

But perhaps you are running the IF within the same code block that sets the variable. Now you can't use normal expansion. The solution is to transfer the inner variable to a FOR variable.

(
  :: Some code that sets the value of var2 
  ::
  for /f "delims=" %%A in ("!var2!") do if "!var1:%%A=!" neq "!var1!" echo It contains %%A
)

answered Feb 21, 2013 at 4:22

dbenham

132k29 gold badges273 silver badges410 bronze badges

1 Comment

Andrew Over a year ago

Thank you for your input. This solution worked for me since the IF is indeed running within the same code block that sets the variable.

Patrick Meinecke · Accepted Answer · 2013-02-20 16:54:00Z

3

This is the simplest way in my opinion.

echo %VAR1% | find /i "%VAR2%" >nul && echo %VAR2% was found!

Replace && with || for if not found.

answered Feb 20, 2013 at 16:54

Patrick Meinecke

4,2112 gold badges20 silver badges26 bronze badges

Collectives™ on Stack Overflow

How do I replace a string variable within a string variable in my cmd batch file?

4 Answers 4

2 Comments

1 Comment

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

2 Comments

1 Comment

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related