Access a PHP array with Perl

You've discovered one of the many reasons why code makes for bad config files. You should move the information to an actual config file, and access that file from both that .php file and from Perl.

JSON would make a decent file format here.

{
   "database": {
      "master": {
        "hostname": "fd35:4776:6804:2:a::1",
        "password": "password"
      },
      "slave": {
        "hostname": "fd35:4776:6804:2:2::2",
        "password": "password",
        "profile":  true
      }
   }
}

The Perl code would be

use JSON::XS qw( decode_json );
open (my $fh, '<:raw', $config_path)
   or die("Can't open config file $config_path: $!\n");
my $file; { local $/; $file = <$fh>; }
my $config = decode_json($file);

On the PHP side, just replace the contents of the file you showed in your post with code to read the config file. I don't know PHP, but it should be quite simple. A quick search shows it might be

return json_decode(file_get_contents($config_path));

It would be simple to provide a short PHP program that dumps the array to a file in JSON format. That file can then be read from Perl using the JSON module.

This is all that is necessary.

<?php
  $array = include 'array.php';
  $fh = fopen('array.json', 'w');
  fwrite($fh, json_encode($array));
  fclose($fh);
?>

The resultant JSON file can then be read in a Perl program, like so:

use strict;
use warnings;

use JSON 'from_json';

my $data = do {
  open my $fh, '<', 'array.json' or die $!;
  local $/;
  from_json(<$fh>);
};

use Data::Dump;
dd $data;

output

{
  database => {
    master => { hostname => "fd35:4776:6804:2:a::1", password => "password" },
    slave  => {
                hostname => "fd35:4776:6804:2:2::2",
                password => "password",
                profile  => bless(do{\(my $o = 1)}, "JSON::XS::Boolean"),
              },
  },
}

There is PHP::Include, which uses a source filter to let you have PHP blocks in your Perl code to declare variables. It also has a read_file() function that applies such a filter to a single PHP file.

But it seems to expect that your PHP has assignments (e.g. $config = array('database' => array(...) and changes those to Perl variable declarations.

In a few minutes of playing with it, I couldn't get it to do anything useful with your PHP code that uses return.

If you want a more "native Perl" solution, you can pretty much* just search and replace all your "array(" and their matching ")" to "{" and "}". That'll give you a perl datastructure called a "hash of hashes" (note: Unlike PHP, Perl refers to arrays with integer indicies as arrays (and uses the @ sigil to denote variables containing them), but refers to array-like things with string indicies as "hashes" (and uses the % sigil to denote variables containing them)). The Perl keywords/concepts you probably want to read up on are:

Perl Data Structures: http://perldoc.perl.org/perldsc.html

and specifically the Hash Of Hashes section: http://perldoc.perl.org/perldsc.html#HASHES-OF-HASHES

and if you dont understand what $hashref = \%hash and %hash{key} and $hashref->{key} mean in Perl, you'd want to read http://perldoc.perl.org/perlref.html

Example code (note how similar the getConfig subroutine is to your PHP code):

#!/usr/bin/perl
use strict;
use warnings;

my $config=getConfig();

print "Database master host = " . $config->{database}{master}{hostname};
print "\n";

print "Database master password = " . $config->{database}{master}{password};
print "\n";

print "Database slave profile = " . $config->{database}{slave}{profile};
print "\n";

sub getConfig{
  return {
    'database' => {
        'master' => {
            'hostname' => 'fd35:4776:6804:2:a::1',
            'password' => 'password'
        },
        'slave' => {
            'hostname' => 'fd35:4776:6804:2:2::2',
            'password' => 'password',
            'profile'  => 'true'
        }
    }
  };
}

• I said "pretty much", because your sample data used the bare word 'true' for the slave->profile value - that's a syntax error in Perl - you can change it to a bare 1, or quote the value as "true" to make it work. In Perl, the digit zero, the string "0" or the empty/nul string "" all evaluate to "false" in a boolean context, anything else evaluates to "true". Take care if you choose to automate PHP to Perl translation, there may be other PHP-isms which could catch you out like that.