Suppress output of a block if one command fails (and output a custom error message)

Question

The title pretty much sums it up, but I'll elaborate on my question. Out of curiosity I've been putting commands in a block (usually with one command that won't work) and seeing if I can suppress the error messages and output a custom one. I tried two methods, the first one failed but the second worked.

1

@echo off
(
    echo Blah
    ehco Blah & rem Intentional mistake
    echo Blah
) 2>nul||echo One of the commands failed.
pause>nul

Output:

Blah
Blah

2

@echo off
call :block 2>nul||echo One of the commands failed.
pause>nul
exit
:block
(
    echo Blah
    ehco Blah & rem Intentional mistake
    echo Blah
)
goto :eof

Output:

Blah
Blah
One of the commands failed.

So, I've got the the second part of my question answered, now I just need to know how to (if one of the commands failed) suppress any output except the custom error message. So, the desired output would be One of the commands failed.. How would I go about doing this?

NOTE: I've heard that you can do something like echo Blah 2>&1nul or something like that, and I guess that would be the way to go. But I'm also guessing that would make it suppress the output every time the command is run, not just when there's an error message.

Also, in your answer, if you could do a brief explanation of why the first script failed, that would be dandy.

Question is - how did batch 2 fail? The answer may surprise you. Try correcting the EHCO and see what you get... — Magoo
– Magoo, Commented Mar 7, 2013 at 4:10
@Peter I don't see how it failed. When I corrected the (intentional) typo, it gave the expected output of 3 blahs and no error message. What are you referring to here? — BDM
– BDM, Commented Mar 7, 2013 at 4:17

dbenham · Accepted Answer · 2013-03-07 04:18:21Z

Very interesting topic, but you haven't solved anything - you fooled yourself :-)

I run a slight variation of your code, and things no longer work like you are expecting!

@echo off
:: clear any existing error
call;

echo %errorlevel%
(
    echo Blah
    ehco Blah & rem Intentional mistake
    echo Blah
) 2>nul||echo One of the commands failed.
echo %errorlevel%

echo(
echo --------------------------
echo(

echo %errorlevel%
call :block 2>nul||echo One of the commands failed.
echo %errorlevel%
exit /b

:block
echo Blah
echo Blah
echo Blah
exit /b

--- output ---

0
Blah
Blah
9009

--------------------------

9009
Blah
Blah
Blah
One of the commands failed.
9009

Normally, the command after || only fires if the prior command failed. The || operator normally does not read the %ERRORLEVEL% variable directly, it usually detects the error status of the prior command directly.

In the first set of code, one of the commands failed, and the ERRORLEVEL was set to 9009. But the last command in the block succeeded, so the conditional failure message does not fire.

The second block of code uses a CALL. When CALL is executed, the current %ERRORLEVEL% at time of return is normally used as the return state for the CALL command. The ERRORLEVEL was 9009 upon routine entry, and none of the commands within the routine clear the error, so 9009 is returned as the error status for the CALL statement. The return code can be forced to any value by specifying the errorlevel as an additional parameter after EXIT /B. For example, exit /b 0.

It can get a bit tricky trying to figure out which commands always set the ERRORLEVEL, and which commands only set the ERRORLEVEL if there was an error. I believe internal commands only set ERRORLEVEL when there is an error, and do not clear any prior ERRORLEVEL if the command succeeded. (I'm assuming .BAT extension. I believe .CMD extension changes the behavior)

Most (all?) external commands always set the ERRORLEVEL. It is up to the executable, but most external commands return 0 for success and non-zero for failure.

Since a block of code may contain a mixture of internal and external commands, you cannot assume the final ERRORLEVEL will be non-zero if any of the commands failed. An intervening external command may have cleared the ERRORLEVEL. You should check the return code of each command and set your error variable to preserve the existence of an error within your block. You can then explicitly return the error code you want with EXIT /B.

The only way I can think to only print stdout when all commands succeed is to redirect all stdout to a temporary file, and keep tabs as to whether any command fails. At block end, you can TYPE the temp file contents if and only if there was no error. Then delete the temp file regardless.

Well, it was a fun little experiment anyway, even if it is impractical in any batch file known to man. Oh well, thanks anyway.

Magoo · Accepted Answer · 2013-03-07 05:09:48Z

Here's my test batch:

@echo OFF
call :block 2>nul||echo One of the commands failed 1.
call :block2 2>nul||echo One of the commands failed 2.
GOTO :eof

:block
(
    echo Blah
    ehco Blah & rem Intentional mistake
    echo Blah
)
goto :eof
:block2
(
    echo Blah
    echo Blah & rem Intentional mistake
    echo Blah
)
goto :eof

Running this produces

Blah Blah One of the commands failed 1. Blah Blah Blah One of the commands failed 2.

regardless of whether it was saved as .bat or .cmd

I'd go along with the stale errorlevel theory - forcing errorlevel to 0 before calling the BLOCK2 subroutine fixed the problem.

Hence the behaviour you obtain depends on the existing errorlevel setting - and you may get unexpected results...

Collectives™ on Stack Overflow

Suppress output of a block if one command fails (and output a custom error message)

1

2

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1

2

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related