adding a default namespace in xquery

Question

I have an xquery file that transforms from a.xml to b.xml. Below is an example of my x-query:

<TestMessage>
    <Header>
      <MessageType>
           {for $x in doc("input.xml")//Test/NewHeader return 
        if ($x/MessageType/text() = "FIRST") then "FirstMessageType"
        else "SecondMessageType"
    }   
      </MessageType>
    </Header>
 </TestMessage>

This works fine and populates my MessageType properly. But I need to add a namespace as an attribute to the TestMessage element. So, when I do,

<TestMessage xmlns="http://www.testsource.com/TestMessage">
    <Header>
      <MessageType>
           {for $x in doc("input.xml")//Test/NewHeader return 
        if ($x/MessageType/text() = "FIRST") then "FirstMessageType"
        else "SecondMessageType"
    }   
      </MessageType>
    </Header>
 </TestMessage>

The xquery result has an empty MessageType element. I haven't changed anything except add the namespace in the x-query document. But I don't understand why this gives me a wrong resultant xml.

Any help would be greatly appreciated.

thanks a lot!

wst · Accepted Answer · 2013-03-12 15:33:20Z

2

When you add a default namespace to the TestMessage element, that namespace is also applied to the XPath you are executing underneath it: doc("input.xml")//Test/NewHeader and ($x/MessageType/text().

If that content doesn't have a namespace, then the easiest thing to do would be to declare a namespace prefix in the XML root: xmlns:test="http://www.testsource.com/TestMessage, and prefix all of the elements: <test:TestMessage xmlns:test="http://www.testsource.com/TestMessage>, <test:Header> and so on.

One way to get around this is to execute the no-namespace XQuery code outside of the default-namespaced XML:

declare function local:get-message-type()
{
  for $x in doc("input.xml")//Test/NewHeader 
  return 
    if ($x/MessageType/text() = "FIRST") 
    then "FirstMessageType"
    else "SecondMessageType"
};

<TestMessage xmlns="http://www.testsource.com/TestMessage">
    <Header>
      <MessageType>
           { local:get-message-type() }   
      </MessageType>
    </Header>
</TestMessage>

edited Mar 12, 2013 at 15:33

answered Mar 12, 2013 at 15:06

wst

11.8k1 gold badge27 silver badges41 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

ridermule Over a year ago

But the root element of my resultant xml should look exactly like this: <TestMessage xmlns="testsource.com/TestMessage">

wst Over a year ago

Other than the presentation, there's no difference in the resultant XML using a default namespace or a namespace prefix. Any application will treat them the same. However, see the updated solution for an alternative.

Joe Wicentowski Over a year ago

@wst is correct. This is called "namespace inheritance" in XQuery. For more on this, see docs.marklogic.com/guide/xquery/namespaces#id_49014.

Chase Lundell Over a year ago

Wow I was struggling to figure out why I kept getting an empty response from my xpath inside of the xml that had a declared namespace like you do there with xmlns. Using a function outside that namespace to get the info and plug it in thereby inheriting the specified namespace did the trick! I couldn't figure out a cleaner way and I really appreciate this answer!

Collectives™ on Stack Overflow

adding a default namespace in xquery

1 Answer 1

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related