add a column to csv file in visual basic

You have a first row of keywords:

"B,C,D,E"

but you want to insert "A" at the beginning, for instance, to have

"A,B,C,D,E"

You can read the entire line, and split on comma (,). Then rebuild the string in a loop, with a special case for the index in which you want to inert the new keyword.

Dim keywords As String
Dim newKeywords As String
Dim arr() As String
Dim keywordToInsert As String
Dim i As Integer

keywords = "B,C,D,E"
keywordToInsert = "A"

arr = Split(keywords, ",")

For i = 0 To UBound(arr) Step 1
    If i = 0 Then
        newKeywords = keywordToInsert
    End If
    newKeywords = newKeywords & "," & arr(i)
Next i

This gives you your keywords. Using this loop, you should be able to come up with your own loop to read through each additional row and operate on the first column like this.

This assumes you know the columns in the CSV file:

Private Sub RewriteFile(ByRef the_sFileName As String)

    Dim sFileNameTemp   As String
    Dim iFileNoInput    As Integer
    Dim iFileNoOutput   As Integer
    Dim iField1         As Integer
    Dim sField2         As String
    Dim datField3       As Date

    ' Temporary file name.
    sFileNameTemp = the_sFileName & ".tmp"

    iFileNoInput = FreeFile
    Open the_sFileName For Input As #iFileNoInput

    iFileNoOutput = FreeFile
    Open sFileNameTemp For Output As #iFileNoOutput

    Do Until EOF(iFileNoInput)
        ' Read in each field of each line into a separate variable, then write to temporary file together with new field. (If you don't know a field's type, use Variants)
        Input #iFileNoInput, iField1, sField2, datField3
        Write #iFileNoOutput, Elaborate(iField1, sField2), iField1, sField2, datField3
    Loop

    Close #iFileNoOutput
    Close #iFileNoInput

    ' Delete the original file, and replace with new file.
    Kill the_sFileName
    Name sFileNameTemp As the_sFileName

End Sub

Or I might upload a raw csv file into a datatable, visualize it in a datagrid in the form and then add a column to the datatable directly