Why does my clojure.core.logic nonmember function return two values?

Question

I'm trying to implement the opposite of membero in clojure.core.logic, but it's returning two values instead of one. Otherwise, it works fine (returns nothing when the value is in the list, and something when it is not).

(defne nonmembero
  "A relation where l is a collection, such that l does not contain x"
  [x l]
  ([_ ()])
  ([_ [head]]
     (!= x head))
  ([_ [head . tail]]
     (!= x head)
     (nonmembero x tail)))

Example runs:

user> (run* [x] (nonmembero 1 [2 3 4 5]))
(_0 _0)
user> (run* [x] (nonmembero 1 [2 3 1 4 5]))
()

Ankur · Accepted Answer · 2013-05-04 07:02:07Z

3

You don't need the second pattern i.e the [_ [head]. This is causing a new branch in search space of core.logic engine and hence leads to the 2 output. The last pattern i.e [head . tail] is enough to handle the case where you have only one element in the list. Now your solution becomes:

(defne nonmembero
  "A relation where l is a collection, such that l does not contain x"
  [x l]
  ([_ ()])
  ([_ [head . tail]]
     (!= x head)
     (nonmembero x tail)))

answered May 4, 2013 at 7:02

Ankur

33.7k2 gold badges50 silver badges73 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

mattias · Accepted Answer · 2016-12-14 09:01:08Z

0

Something is wrong with the code above. It finds a solution for the following

(run* [q](== q 1)(nonmembero q [1 2 3]))  =>  (1)

The following gives the expected result

(run* [q](== q 1)(nonmembero2 q [1 2 3]))  => ()

where nonmembero2 is

(defn nonmembero2
  [x l]
  (fresh [h t]
    (conde
      [(== l ())]
      [(conso h t l)
       (!= x h)
       (nonmembero2 x t)])))

answered Dec 14, 2016 at 9:01

mattias

9005 silver badges18 bronze badges

Collectives™ on Stack Overflow

Why does my clojure.core.logic nonmember function return two values?

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related