Perl - build 2D array from 2 arrays of equal length

Question

So I should preface this by saying I've actually solved this, but the syntax is horrible so I want to see if theres a Perl-ish way of doing it which is nicer.

I have two arrays of length n (@genes and @names). I want to combine them into a single 2D array of paired values.

My approach right now is;

$Num = Number of elements in each array

my @genes = ();
foreach my $i ( 0 .. $num-1 ) {
    foreach my $j ( 0 .. 1 ) {
    if ($j == 0){ push @{ $genes[$i] }, $names[$i];}
    if ($j == 1){ push @{ $genes[$i] }, $lengths[$i];}
    }
}

But this requires an explicit line for each additional column (right now I have two - names and length). Also it's hideous. Code only a mother could love.

Any thoughts. Note that

@genes = (\@lengths, \@names);

Does not achieve what I want.

You did mean to say that you have two arrays @names and @length that you want to combine into a 2D-array @genes, I take it? — TLP
– TLP, Commented Jun 21, 2013 at 0:37

Community · Accepted Answer · 2017-05-23 12:21:34Z

5

You can at least do this:

foreach my $i ( 0 .. $num-1 ) {
    push @genes, [$names[$i], $lengths[$i]];
}

If you don't care about the input arrays, you can consume them:

push @genes, [shift @names, shift @lengths] while @names;

There are also some modules you can use for iterating over multiple lists. For example, using List::MoreUtils::each_array:

use List::MoreUtils qw( each_array );
my $it = each_array( @names, @lengths );
while (my ($n, $l) = $it->()) {
    push @genes, [$n, $l];
}

Further, with List::MoreUtils::pairwise:

use List::MoreUtils qw( pairwise );
@genes = pairwise{ [our $a, our $b] } @names, @lengths;

Suggested by ysth, with Algorithm::Loops::MapCarE:

use Algorithm::Loops 'MapCarE';
@genes = MapCarE { \@_ } \( @names, @lengths );

edited May 23, 2017 at 12:21

CommunityBot

11 silver badge

answered Jun 20, 2013 at 23:54

perreal

98.7k23 gold badges159 silver badges187 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Alex Over a year ago

Awesome - that first syntax is clearly a much cleaner implementation (and in hind-site not in anyway Perl specific)

Borodin · Accepted Answer · 2013-06-21 01:00:46Z

4

You could write

my @genes = map [ $names[$_], $lengths[$_] ], 0 .. $#names;

answered Jun 21, 2013 at 1:00

Borodin

127k9 gold badges72 silver badges146 bronze badges

Comments

Julian Fondren · Accepted Answer · 2013-06-21 03:35:34Z

Incidentally, your original code can be cleaned up just by removing some unnecessary logic:

foreach my $i ( 0 .. $num-1 ) {
    foreach my $j ( 0 .. 1 ) {
        if ($j == 0){ push @{ $genes[$i] }, $names[$i];}
        if ($j == 1){ push @{ $genes[$i] }, $lengths[$i];}
    }
}

You're looping over 0 and 1, then testing if you're on 0 or 1, then performing one action or the other? Just perform the two actions each time:

foreach my $i ( 0 .. $num-1 ) {
  push @{$genes[$i]}, $names[$i];
  push @{$genes[$i]}, $lengths[$i]
}

Possibly you started out wanting to loop over the indexes, then thought you couldn't do this since the internal arrays didn't exist yet, and fell back to this push construction. But, er, the arrays don't exist until you push onto them here, either. Looping over the indexes was fine:

my @helper = (\@names, \@lengths);
foreach my $i ( 0 .. $#names ) {
    foreach my $j ( 0 .. 1 ) {
        $genes[$i][$j] = $helper[$j][$i];
    }
}

Collectives™ on Stack Overflow

Perl - build 2D array from 2 arrays of equal length

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related