Splitting specific strings in an array?

Question

I have an array (@myarray) with strings as such:

rs30000489
rs903484
rs24567;rs324987;rs234985
rs5905002
rs32456;rs2349085

When I match another similar (@otherarray) array without strings with semicolons and multiple rsIDs, with the following code:

for $1(0 .. $#otherarray) {
    for $m(1 .. $#myarray) {
        if ($myarray[$m] =~ /$otherarray[$i]/i) { 
            $IDmatch = 1;
        }
    }
}

The script does not match any of the IDs within strings with semicolons. I tried splitting the semicolon strings like such:

foreach $string (@myarray) {
    if ($string =~ m/;/) {
        push (@newarray, $string);
    }
}

Which returns the array @new:

rs24567;rs324987;rs234985
rs32456;rs2349085

Which I then try to split it by a common character as such:

foreach $line (@new) {
    $line =~ tr/;//d;
    $line =~ s/rs/ rs/g;
    $line = split (/ /);
}

But when I print the @new array it just returns zeros. I know this must have something to do with my loop because I have trouble working with loops in perl. Please let me know if you have any ideas! Thanks!

This sounds like an XY-problem. What is it you really want to do? Match two lists of IDs against each other? — TLP
– TLP, Commented Jul 23, 2013 at 12:00
Also, you should be more careful when writing crucial descriptions. What does this mean: without strings with semicolons and multiple rsIDs Without strings with semi-colons sounds like its only semi-colons. You should almost always show instead of describe. — TLP
– TLP, Commented Jul 23, 2013 at 12:03
and your 'split' is not really a split. Its a matching for ; and then pushing it to @new — user1558455
– user1558455, Commented Jul 23, 2013 at 12:04
@TLP yes, and I mean the array I am checking against does not have any instances of strings such as rs#;rs#;rs# like the '@myarray' array does — user2560686
– user2560686, Commented Jul 23, 2013 at 12:27
@user2560686 Now, that might make sense to you, but to me you're only saying that @otherarray has other kinds of strings. Which doesn't really say anything, if you think about it. To make things easier, you should just show sample data, like you did with the first array. — TLP
– TLP, Commented Jul 23, 2013 at 13:53

Borodin · Accepted Answer · 2013-07-23 12:12:12Z

2

You don't say what you want to do with these two arrays, but if I understand your question peoperly it sounds like you probably want to find all those rsIDs that appear in both lists.

This program works by converting the first array (please use better names than myarray and otherarray) into a hash that has all the IDs as keys. Then it uses grep to find all those in the second array that appear in the hash, pushing them to array @dups.

use strict;
use warnings;

my @myarray = qw(
  rs30000489
  rs903484
  rs24567;rs324987;rs234985
  rs5905002
  rs32456;rs2349085
);

my @otherarray = qw(
  rs3249487
  rs30000489
  rs325987
  rs324987
  rs234967
  rs32456
  rs234567
);

my %rsids = map { $_ => 1 } map { split /;/ } @myarray;

my @dups = grep $rsids{$_}, @otherarray;

print "$_\n" for @dups;

output

rs30000489
rs324987
rs32456

answered Jul 23, 2013 at 12:12

Borodin

127k9 gold badges72 silver badges146 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

user1558455 · Accepted Answer · 2013-07-23 12:00:40Z

Just to a few things about the loops in Perl. You wrote the for loop in 2 different ways.

for $1(0 .. $#otherarray) { ... }

and

foreach $line (@new) { ... }

You can write the first loop loop exactly same like the 2nd.

foreach $1 ( 0..$#otherarray) { .. }

or much better

foreach my $other_array_content ( @otherarray) { .. }

The $1 you used is a special char (used in Regular Expressions).

Then you can use the split inside the foreach loop as well.

foreach my $data (@data) {
  foreach (split /;/,$data) {

  }
}

Here is a short solution in a nutshell of your problem:

my @checked = qw(rs30000489
  rs9033484
  rs2349285
  rs5905402
  rs32456
);

my $idMatch = 0;
my @data    = <DATA>;

foreach my $data ( @data ) {
  foreach my $checked ( @checked ) {
    if ( $data =~ m/;/ ) {
      foreach my $data2 ( split /;/, $data ) {
        if ( $checked eq $data2 ) {
          $idMatch = 1;
        }
      }
    } else {
      if ($data eq $checked) {
        $idMatch = 1;
      }
    }
  }
}

print $idMatch;

__DATA__

rs30000489
rs903484
rs24567;rs324987;rs234985
rs5905002
rs32456;rs2349085

shawnhcorey · Accepted Answer · 2013-07-23 12:34:52Z

If you're looking for unique items, the first thing you should think of is hashes. Try:

#!/usr/bin/env perl

use strict;
use warnings;

# --------------------------------------

use charnames qw( :full :short   );
use English   qw( -no_match_vars );  # Avoids regex performance penalty

use Data::Dumper;

# Make Data::Dumper pretty
$Data::Dumper::Sortkeys = 1;
$Data::Dumper::Indent   = 1;

# Set maximum depth for Data::Dumper, zero means unlimited
local $Data::Dumper::Maxdepth = 0;

# conditional compile DEBUGging statements
# See http://lookatperl.blogspot.ca/2013/07/a-look-at-conditional-compiling-of.html
use constant DEBUG => $ENV{DEBUG};

# --------------------------------------
#       Name: unique
#      Usage: %hash = unique( @array );
#    Purpose: Create a hash of unique keys from array items.
# Parameters: @array -- May have multiple entries separated by a semi-colon
#    Returns:  %hash -- Unique keys of array items
#
sub unique {
  my @array = @_;
  my %hash  = ();

  for my $item ( @array ){
    my @items = split m{ \; }msx, $item;
    $hash{$_} ++ for @items;
  }

  return %hash;
}

# --------------------------------------

my @myarray = qw(
  rs30000489
  rs903484
  rs24567;rs324987;rs234985
  rs5905002
  rs32456;rs2349085
);

my @otherarray = qw(
  rs3249487
  rs30000489
  rs325987
  rs324987
  rs234967
  rs32456
  rs234567
);

my %my_hash = unique( @myarray );
print Dumper \%my_hash if DEBUG;

my %other_hash = unique( @otherarray );
print Dumper \%other_hash if DEBUG;

my %intersection = ();
for my $item ( keys %my_hash ){
  if( exists $other_hash{$item} ){
    $intersection{$item} ++;
  }
}
print Dumper \%intersection if DEBUG;

Collectives™ on Stack Overflow

Splitting specific strings in an array?

3 Answers 3

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related