Array loses values after loop in Vbscript

Question

This is the code:

'creates the msxml object
Set xmlDoc = CreateObject("Msxml2.DOMDocument.6.0")
Dim retVal

'load the xml data of the script
retVal=xmlDoc.load(argFilePath)

Dim fso, folder, sFolder
Dim xmlDataPath, curNode

'get input folder
Set curNode=xmlDoc.selectSingleNode("//ScriptXmlData/inputFilePath")
Dim inputFolder, outputFolder, hotLoc
inputFolder=CSTR(curNode.text)

'location of jdf files
sFolder=inputFolder

'creating file getting object
Set fso = CreateObject("Scripting.FileSystemObject")
Set folder = fso.GetFolder(sFolder)

Dim amount, fName, arrC, i
i=0

'loop for getting amounts
For each folderIdx In folder.files
    If fso.GetExtensionName(folderIdx.Name) = "jdf" Then

        'increase array size
        Redim arrC(i)

        'get folder name
        fName=folderIdx.Name

        'get file path
        xmlDataPath = sFolder+"\"+fName

        'load the xml data of the script
        retVal = jdfDoc.load(xmlDataPath)

        'get amount
        Set curNode = jdfDoc.selectSingleNode("//jdf:JDF/jdf:ResourceLinkPool/jdf:ComponentLink")
        amount = curNode.getAttribute("Amount")

        'Create array that holds amount
        arrC(i)=amount
        i=i+1

    End If
Next

wscript.echo arrC(0)
wscript.echo arrC(1)
wscript.echo arrC(2)

Our problem is that once arrC exits the loop, some of its values go missing. For example, inside the loop our array is:

arrC(0)=100
arrC(1)=150
arrC(2)=200

Once it leaves the loop, as in the test in the end of the code, its values are :

arrC(0)=""
arrC(1)=""
arrC(2)=200

Can someone please explain?

Thank you!

Ansgar Wiechers · Accepted Answer · 2013-08-04 14:25:20Z

2

ReDim doesn't preserve the elements of an array when used without the keyword Preserve. Change the line

Redim arrC(i)

into

Redim Preserve arrC(i)

You don't need an index variable, BTW. When you initialize the arrC as an empty array outside the loop, you can use the upper bound as your index:

ReDim arrC(-1)

For Each folderIdx In folder.files
  If fso.GetExtensionName(folderIdx.Name) = "jdf" Then
    ...
    ReDim Preserve arrC(UBound(arrC)+1)
    arrC(UBound(arrC)) = amount
  End If
Next

However, since ReDim Preserve actually creates a new array and copies the existing elements from the old one, it's bound to perform poorly with increasing array size. You may want to use an array list instead:

Set arrC = CreateObject("System.Collections.ArrayList")

For Each folderIdx In folder.files
  If fso.GetExtensionName(folderIdx.Name) = "jdf" Then
    ...
    arrC.Add amount
  End If
Next

edited Aug 4, 2013 at 14:25

answered Aug 4, 2013 at 14:18

Ansgar Wiechers

202k27 gold badges286 silver badges363 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Neta Over a year ago

Very thorough!! Thank you very much you are great! Can you think of a way this would happen with a variable? Happened to us before but we were able to avoid it...

Ansgar Wiechers Over a year ago

What kind of variable and in which context?

Neta Over a year ago

We created our own "Replace" function, which was in a loop. We put the result string in a variable. The loop ran 3 times, each replacing something else, then outside the loop the variable would lose its value

Ansgar Wiechers Over a year ago

Might have been an issue with the scope of the variable. Hard to say without seeing the actual code.

Collectives™ on Stack Overflow

Array loses values after loop in Vbscript

1 Answer 1

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related