Reading a text file line by line and storing it in an array using batch script

Question

I want to read a text file and store each line in an array. When I used the code below, "echo %i%" is printing 0 every time and only array[0] value is getting assigned. But in "set n=%i%",n value is assigned as the last incremented I value.Also "@echo !array[%%i]!" is printing like !array[0]! instead of printing the value. Is there any syntax error in the code?

set /A i=0

for /F %%a in (C:\Users\Admin\Documents\url.txt) do (

set /A i+=1

echo %i%

set array[%i%]=%%a

)

set n=%i%

for /L %%i in (0,1,%n%) do @echo !array[%%i]!

possible duplicate of Batch files: How to read a file?

jeb
– jeb

2013-09-18 09:00:28 +00:00
Commented Sep 18, 2013 at 9:00 — jeb
– jeb, Commented Sep 18, 2013 at 9:00

foxidrive · Accepted Answer · 2013-09-18 10:37:38Z

17

Here's a method that is useful at times and very similar to your code:

@echo off
set "file=C:\Users\Admin\Documents\url.txt"
set /A i=0

for /F "usebackq delims=" %%a in ("%file%") do (
set /A i+=1
call echo %%i%%
call set array[%%i%%]=%%a
call set n=%%i%%
)

for /L %%i in (1,1,%n%) do call echo %%array[%%i]%%

answered Sep 18, 2013 at 10:37

foxidrive

41.4k11 gold badges61 silver badges71 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Endoro · Accepted Answer · 2013-09-18 08:35:01Z

3

@echo off &setlocal enabledelayedexpansion
for /F "delims=" %%a in (C:\Users\Admin\Documents\url.txt) do (
    set /A count+=1
    set "array[!count!]=%%a"
)
for /L %%i in (1,1,%count%) do echo !array[%%i]!

Inside a code block you need delayed expansion and !variables!.

answered Sep 18, 2013 at 8:35

Endoro

37.7k8 gold badges54 silver badges64 bronze badges

Comments

Magoo · Accepted Answer · 2013-09-18 08:54:22Z

0

@ECHO OFF
SETLOCAL
FOR /f "tokens=1*delims=:" %%i IN ('findstr /n /r "$" url.txt') DO SET max=%%i&SET array[%%i]=%%j
FOR /l %%i IN (1,1,%max%) DO CALL ECHO(%%array[%%i]%%
GOTO :EOF

provided no line begins ":"

answered Sep 18, 2013 at 8:54

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Comments

Maximus · Accepted Answer · 2013-09-18 07:37:28Z

-1

Read set /? description about environment run-time linking. When you are using %i% inside for - it is pre-expanded before for execution. You need to use !i! instead.

answered Sep 18, 2013 at 7:37

Maximus

10.9k8 gold badges50 silver badges66 bronze badges

3 Comments

NagaLakshmi Over a year ago

Thanks Maximus,I replaced %i% with !i!. Now "echo !i!" is printing !i! and "array[!i!]=%%a" is assigning the values as array[!i!]. The value if i is not applied while using "!".

Maximus Over a year ago

I think you have not read set /?. Read it carefully about cmd and /v switch.

dbenham Over a year ago

@NagaLakshmi - Within a batch file, you can use setlocal enableDelayedExpansion to do just that.

Collectives™ on Stack Overflow

Reading a text file line by line and storing it in an array using batch script

4 Answers 4

Comments

Comments

Comments

3 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

Comments

Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related