Using RegEx for javascript string parameter encoding

Question

Summary

Can you use a regular expression to match multiple characters, but replace individual characters with specific replacements.

For instance, replace \ with \\ and replace " with \x22 and replace ' with \x27.

It is my understanding that this is simply not possible, as you can use the captured sub-matches within the expression, but not with any level of logic that would allow you to conditionally output text if a sub-match took place.

The following VB.NET code is obviously totally incorrect, but gives you an idea of my thinking... (i.e. if there was a replacement command that allowed you to say "if sub-match 1 happened, then output \\ instead")

RegEx.Replace(text, "(\)?("")?(')?", "{if($1,'\\')}{if($2,'\x22')}{if($2,'\x27')}")

(This would be for use with .NET RegEx class, but would be useful for use with javascript RegExp class)

Background

More for interest than actual need, but I've been playing with encoding text for use within javascript parameters. (Well, the need is certainly there, but the interest is efficiency.)

I've been using the standard String.Replace, and doing some tests for performance with the following two functions...

Public Function GetJSSafeString(ByVal text As String) As String
    Return text.Replace("\", "\\").Replace("""", "\x22").Replace("'", "\x27")
End Function
Public Function GetJSSafeString2(ByVal text As String) As String
    If text.Contains("\") Then
        text = text.Replace("\", "\\")
    End If
    If text.Contains("""") Then
        text = text.Replace("""", "\x22")
    End If
    If text.Contains("'") Then
        text = text.Replace("'", "\x27")
    End If
    Return text
End Function

Using two strings, both around 200 characters in length - the first does not contain any characters to be converted - the second contains one of each character to be converted (\"'). I ran each of the two strings through the two functions 100000 times each.

The four results are coming out (in total-milliseconds) roughly as...

GetJSSafeString, no converted characters: 182.0364
GetJSSafeString, converted characters: 316.0632

GetJSSafeString2, no converted characters: 60.012
GetJSSafeString2, converted characters: 354.0708

So obviously GetJSSafeString2 is best if there are no replacement, and worst if there are characters to convert (but not much worse, so looks like the better choice).

But it got me thinking... could this be done with a single regular expression?

And if so, would it be faster than either of the two above functions?

psxls · Accepted Answer · 2013-10-03 12:17:07Z

2

The solution in JavaScript:

var text="this is a test \\ with \"things\" to ' replace";
var h={'\\':'\\\\', '"':"\\x22", "'":"\\x27"}; //we define here the replacements
text=text.replace(/("|\\|')/g,function(match){return h[match]});
alert(text); //prints: this is a test \\ with \x22things\x22 to \x27 replace

Note: this document on replace is worth reading

edited Oct 3, 2013 at 12:17

answered Oct 3, 2013 at 10:36

psxls

6,9456 gold badges34 silver badges50 bronze badges

Sign up to request clarification or add additional context in comments.

6 Comments

freefaller Over a year ago

Thanks @psxls... I have absolutely zero knowledge of Perl, so I simply have no idea how that would translate to either javascript or VB.NET

psxls Over a year ago

NP, I'm almost finished with the conversion, I'll update the answer in the next hour.

freefaller Over a year ago

Don't kill yourself over it... it was purely for interest, and possibly efficiency

freefaller Over a year ago

I like it, well done :-) A very minor improvement would be to replace the four h lines with a single var h = { '\\': '\\\\', '"': "\\x22", "'": "\\x27" }; Unfortunately, the primary requirement was for asp.net, as I do say at the end of the summary. I can see the javascript in the title is confusing, as what I need this for is for the encoding of strings for use when calling javascript functions, although the code itself will be created within ASP.NET

freefaller Over a year ago

Your answer did help, but it's not exactly what I was after, so I apologise but I won't be giving you the "correct answer mark" - but I've definitely given you a +1 for it :-) Thanks for your time and effort, as it pointed me in the direction I needed, and gave me the result I was expecting (see my answer)

|

freefaller · Accepted Answer · 2013-10-03 12:21:35Z

Big thanks to @psxls for his answer, which will be useful for future javascript implementation.

His answer made me look at the overloads for the .NET RegEx.Replace function (which to be honest, I should have done in the first place, my bad)... and there is a MatchEvaluator delegate.

So I have implemented the following code as a test (to compliment the code already in my answer)...

Public Function GetJSSafeString3(ByVal text As String) As String
    Return Regex.Replace(text, "(\\|""|')", New MatchEvaluator(AddressOf GetJSSafeString3Eval))
End Function
Public Function GetJSSafeString3Eval(ByVal textMatch As Match) As String
    Select Case textMatch.Value
        Case "\"
            Return "\\"
        Case """"
            Return "\x22"
        Case "'"
            Return "\x27"
    End Select
    Return ""
End Function

And the results are as I expected... that this is far, far less efficient than either of the functions in my original question function. (The following are in milliseconds)

GetJSSafeString, no converted characters: 182
GetJSSafeString, converted characters: 316

GetJSSafeString2, no converted characters: 60
GetJSSafeString2, converted characters: 354

GetJSSafeString3, no converted characters: 477
GetJSSafeString3, converted characters: 856

As the majority of the strings that I will be converting will not contain any of the characters mentioned, I am implementing the GetJSSafeString*2* function, as that is by far the most efficient for the majority of situations.

Collectives™ on Stack Overflow

Using RegEx for javascript string parameter encoding

2 Answers 2

6 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

6 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related