Perl grep nested hashes recursive

Question

I have structure which looks like this (hash of hashes):

%hash=(
Level1_1=> {    
 Level2_1 => "val1",
 Level2_2=> { 
  Level3_1 => "val2",
  Level3_2 => "val1",
  Level3_3 => "val3",
 },
Level2_3 => "val3",
},
 Level1_2=> {   
  Level2_1 => "val1",
  Level2_2=> {  
   Level3_1 => "val1",
   Level3_2 => "val2",
   Level3_3 => "val3",
  },
 Level2_3 => "val3",
 },
 Level1_3=> {   
  Level2_1 => "val1",
  Level2_2 => "val2",
  Level2_3 => "val3",
 });

I would like to grep this nested structure filtered by "val2" And the output should be :

%result=(
    Level1_1=> { Level2_2=> { Level3_1 => "val2"} },
    Level1_2=> { Level2_2=> { Level3_2 => "val2" } },
    Level1_3=> { Level2_2 => "val2" }
    );

My first idea was to use a recursive subroutine like this:

hashwalk_v( \%hash );
sub hashwalk_v
{
    my ($element, @array) = @_;
    if( ref($element) =~ /HASH/ )
    {
   while (my ($key, $value) = each %$element)
   {

     if( ref($value) =~ /HASH/ ) {
      push (@array, $key);
      hashwalk_v($value, @array);
     } else {
      if ( $value =~ "val2") {
       push (@array, $key);
       print $_ .  "\n" for @array;
      } else {
       @array =""; 
      }
     }
   }
 }
}

but unfortunately I can not save the hash key from the previous loop. Any ideas??

mpapec · Accepted Answer · 2013-10-28 08:25:30Z

6

Similar approach,

use Data::Dumper; print Dumper hfilter(\%hash, "val2");

sub hfilter {
  my ($h, $find) = @_;
  return if ref $h ne "HASH";

  my %ret = map {
    my $v = $h->{$_};
    my $new = ref($v) && hfilter($v, $find);

    $new ? ($_ => $new)
      : $v eq $find ? ($_ => $v)
      : ();

  } keys %$h;

  return %ret ? \%ret : ();
}

answered Oct 28, 2013 at 8:25

mpapec

50.7k8 gold badges71 silver badges133 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Eevee · Accepted Answer · 2013-10-28 07:57:20Z

5

Recursion is the right answer, but you seem to have gotten a little confused along the way. :) Build the new hash as you go, one level at a time:

sub deep_hash_grep {
    my ($hash, $needle) = @_;

    my $ret = {};
    while (my ($key, $value) = each %{$hash}) {
        if (ref $value eq 'HASH') {
            my $subgrep = deep_hash_grep($value, $needle);
            if (%{$subgrep}) {
                $ret->{$key} = $subgrep;
            }
        }
        elsif ($value =~ $needle) {
            $ret->{$key} = $value;
        }
    }

    return $ret;
}

answered Oct 28, 2013 at 7:57

Eevee

48.7k11 gold badges100 silver badges128 bronze badges

Collectives™ on Stack Overflow

Perl grep nested hashes recursive

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related