Batch Execute looped commands with successive array values

Question

How can I achieve the following:

set host[0]=\\thisserver
set host[1]=\\thatserver
set host[2]=\\otherserver

set targethost = host[0]


call :do_stuff_with_each_host_in_turn


:do_stuff_with_each_host_in_turn
ping %targethost%
do stuff involving %targethost%
set targethost=%host%[next]
call :do_stuff_with_each_host_in_turn
popd 
EXIT /B

My context is actually to carry out a series of PSexec (running commands remotely) on a long list of servers. I'd like to slim down the code by looping through the function and just use the name of the next server from the host array with each iteration of :do_stuff_with_each_host_in_turn

Many thanks!

dbenham · Accepted Answer · 2013-11-22 17:19:53Z

3

Continuing with Mark's idea, except you don't have to put the hosts in a separate file:

for %%H in (
  \\thisserver
  \\thatserver
  \\otherserver
) do call :do_stuff %%H
exit /b

:do_stuff
ping %1
do stuff involving %1
exit /b

If you really want to use your host "array", then:

set host[1]=\\thisserver
set host[2]=\\thatserver
set host[3]=\\otherserver
set hostCount=3

for /l %%N in (1 1 %hostCount%) do call :do_stuff %%host[%%N]%%
exit /b

:do_stuff
ping %1
do stuff involving %1
exit /b

answered Nov 22, 2013 at 17:19

dbenham

132k29 gold badges272 silver badges410 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Mark · Accepted Answer · 2013-11-22 18:35:21Z

3

While you can do that using an index variable that you increment with set /a, I think you'll find it much more useful to keep your list of servers in a text file, then do something like this:

set SERVERLIST=servers.txt
for /f %%x in (%SERVERLIST%) do call :do_stuff_with_each_host_in_turn %%x
echo Script is done...
exit /b

:do_stuff_with_each_host_in_turn
REM %1 is the value you passed in from your for loop
set SERVER=%1
REM psexec \\%SERVER% -u user -p password etc., etc.

This way is a little easier to follow, and as a bonus, you won't have to hardcode your host names in your script.

edited Nov 22, 2013 at 18:35

answered Nov 22, 2013 at 16:48

Mark

3,7301 gold badge24 silver badges33 bronze badges

Comments

Aacini · Accepted Answer · 2013-11-22 21:01:12Z

1

You can process all array elements with no need of previously count them this way:

for /F "tokens=1* delims==" %%a in ('set host[') do call :do_stuff %%b



:do_stuff
ping %1
do stuff involving %1
exit /b

answered Nov 22, 2013 at 21:01

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

Collectives™ on Stack Overflow

Batch Execute looped commands with successive array values

3 Answers 3

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related