I have an array of elements combined with # which I wish to put in hash , first element of that array as key and rest as value after splitting of that array elements by # But it is not happening.
Ex:
my @arr = qw(9093#AT#BP 8111#BR 7456#VD#AP 7786#WS#ER 9431#BP ) #thousand of data
What I want is
$hash{9093} = [AT,AP];
$hash{8111} = [BR]; and so on
How we can accomplish it using map function. Otherwise I need to use for loop but I wish to use map function.
my %hash = map { my ($k, @v) = split /#/; $k => \@v } @arr;
For comparison, the corresponding foreach loop follows:
my %hash;
for (@arr) {
my ($k, @v) = split /#/;
$hash{$k} = \@v;
}
Use split to split on '#', taking the first chunk as the key, and keeping the rest in an array. Then create a hash using the keys and references to the arrays.
use Data::Dumper;
my @arr = qw( 9093#AT#BP 8111#BR 7456#VD#AP 7786#WS#ER 9431#BP );
my %hash = map {
my ($key, @vals) = split '#', $_;
$key => \@vals;
} @arr;
print Dumper \%hash;
No effort shown in your question, but I am on a code freeze so I'll bite :)
A think that a for loop would be more idiomatic Perl here, process the elements one-by-one, split on # and then assign into your hash:
use strict;
use warnings;
use Data::Dumper;
my @arr = qw(9093#AT#BP 8111#BR 7456#VD#AP 7786#WS#ER 9431#BP );
my %h;
for my $elem ( @arr ) {
my ($key, @vals) = split /#/, $elem;
$h{$key} = \@vals;
}
print Dumper \%h;
That is easy:
%s = (map {split(/#/, $_, 2)} @arr);
Testing it:
$ cat 1.pl
my @arr = qw(9093#AT#BP 8111#BR 7456#VD#AP 7786#WS#ER 9431#BP );
%s = (map {split(/#/, $_, 2)} @arr);
foreach my $key ( keys %s )
{
print "key: $key, value: $s{$key}\n";
}
$ perl 1.pl
key: 7456, value: VD#AP
key: 8111, value: BR
key: 7786, value: WS#ER
key: 9431, value: BP
key: 9093, value: AT#BP
9093 => 'AT#BP' instead of 9093 => [ 'AT', 'BP' ]use strict;
use warnings;
use Data::Dumper;
my @arr = ('9093#AT#BP', '8111#BR', '7456#VD#AP', '7786#WS#ER', '9431#BP' );
my %h = map { map { splice(@$_, 0, 1), $_ } [ split /#/ ] } @arr;
print Dumper \%h;
use strictanduse warningsin effect. For example:Possible attempt to put comments in qw() list.