How do I append text to a file with vim script?

Question

I want a function to append text to a file (not a buffer) in vim. As far as I can see, there is no appendfile(). But the desired functionality can be emulated with readfile() and writefile():

fu! TQ84_log (S)

   let l:f = readfile('my.log')
   call add(l:f, a:S)
   call writefile(l:f, 'my.log')

endfu

Since my.log can grow quite large, I'd rather not read and write the entire file when I want to add a line. So, I came up with another "solution":

fu! TQ84_log (S)
   silent execute "!echo " . a:S . ">> my.log"    
endfu

This works (on windows, that is) as expected. Yet, when I invoke TQ84_log(), that cmd.exe window pops up for a short time. This is a bit distracting.

Is there a better solution for my problem?

If you do not find an alternative, you can avoid the cmd.exe window with shell.vim plugin. — mMontu
– mMontu, Commented Apr 15, 2014 at 17:17
You should use function instead of fu and use more readable variable names. If you don't do that for others at least do that for yourself. — romainl
– romainl, Commented Apr 15, 2014 at 18:36

benjifisher · Accepted Answer · 2014-04-15 17:31:59Z

18

If you have a range of lines in your current buffer that you want to append to the log file, then

:[range]w >> my.log

does exactly what you want. (Well, maybe not exactly. For example, it has the side effect of making my.log the alternate file, and if you plan to use :e# or something, it may mess you up.)

If you already have the log message in a variable, then you could open up a scratch buffer, use append() or :put to add the line(s) to your scratch buffer, then :w >> my.log and close the scratch buffer.

:help special-buffers
:help :put
:help :w

Here is a complete log function. There is room for improvement: the combination of :new and :q may not restore the layout if you have split windows, and :put on an empty buffer leaves you with a blank line that you probably do not want.

function! Mylog(message, file)
  new
  setlocal buftype=nofile bufhidden=hide noswapfile nobuflisted
  put=a:message
  execute 'w >>' a:file
  q
endfun

edited Apr 15, 2014 at 17:31

answered Apr 15, 2014 at 17:17

benjifisher

5,12218 silver badges19 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Sukima Over a year ago

This is perfect, Now I can write to my FIFO easy peasy. I use a fifo to pass text to another computer via ssh.

YAMAMOTO Yuji · Accepted Answer · 2020-02-23 07:55:55Z

9

According to :help writefile():

When {flags} contains "a" then append mode is used, lines are
appended to the file: >
    :call writefile(["foo"], "event.log", "a")
    :call writefile(["bar"], "event.log", "a")

answered Feb 23, 2020 at 7:55

YAMAMOTO Yuji

1,46411 silver badges18 bronze badges

2 Comments

benjifisher Over a year ago

That was added in 7.4.503, released 2014-11-05 according to github.com/vim/vim/releases/tag/v7.4.503, a few months after my answer. Still, good to know and worth an up-vote.

Xopi García Over a year ago

https://vimhelp.org/eval.txt.html#writefile%28%29

Collectives™ on Stack Overflow

How do I append text to a file with vim script?

2 Answers 2

1 Comment

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related