How to use multiple commands in batch using forfiles command?

Question

@ECHO OFF

SET backdir=backup
SET snapshotdir=snapshots
SET worldprefix=world_
SET itdate=%date:~10,4%-%date:~4,2%-%date:~7,2%
SET hour=%time:~0,2%

IF "%hour:~0,1%" == " " SET hour=0%hour:~1,1%

echo Current date: %itdate%. Current hour: %hour%. Current Minute:Second: %time:~3,2%:%time:~6,2%

    forfiles /m "%worldprefix%*" /c (
        echo Copying World: @path
        cmd /c xcopy /e /c /h /i /v /r /y /q @file %snapshotdir%\@file\%itdate%-%hour%-%time:~3,2%-%time:~6,2%
        cmd /c xcopy /e /c /h /i /v /r /y /q @file %backdir%\%itdate%D\worlds\@file
     )

echo Copying Plugins
xcopy /e /c /h /i /v /r /y /q plugins %backdir%\%itdate%D\plugins\
xcopy /e /c /h /i /v /r /y /q %backdir%\%itdate%D %backdir%\%itdate%-%hour%H\

echo Backup Complete (assuming no errors above).  Attempting to remove old files..
forfiles /p "%snapshotdir%" /c "cmd /c rmdir /s /q @path" /d -7
forfiles /p "%backdir%" /m "*H" /c "cmd /c rmdir /s /q @path" /d -2
forfiles /p "%backdir%" /m "*D" /c "cmd /c rmdir /s /q @path" /d -14

PAUSE

I am trying to copy all files with "world_" as a prefix. I run into a problem when I try to use multiple commands in a loop. I have attempted to write the batch script I want above.

dbenham · Accepted Answer · 2014-11-18 14:47:31Z

8

The two commands have absolutely nothing in common, so no, you cannot use parentheses like that.

You must execute all the commands within a single CMD /C. You can concatenate commands on one line using &. I've defined a simple XCOPY "macro" to save a bit of typing.

set XCOPY=xcopy /e /c /h /i /v /r /y /q"
forfiles /m "%worldprefix%*" /c "cmd /c echo Copying World: @path&%XCOPY% @file %snapshotdir%\@file\%itdate%-%hour%-%time:~3,2%-%time:~6,2%&%XCOPY% @file %backdir%\%itdate%D\worlds\@file"

If you escape the quotes, then you can use line continuation to split the logical line accross multiple lines. But then you must also escape the &.

set XCOPY=xcopy /e /c /h /i /v /r /y /q"
forfiles /m "%worldprefix%*" /c ^"cmd /c ^
echo Copying World: @path ^&^
%XCOPY% @file %snapshotdir%\@file\%itdate%-%hour%-%time:~3,2%-%time:~6,2% ^&^
%XCOPY% @file %backdir%\%itdate%D\worlds\@file^"

Or you could put the & in the front of the line so that you don't need to escape it. The line continuation also escapes the first character of the next line:

set XCOPY=xcopy /e /c /h /i /v /r /y /q"
forfiles /m "%worldprefix%*" /c ^"cmd /c ^
echo Copying World: @path^
&%XCOPY% @file %snapshotdir%\@file\%itdate%-%hour%-%time:~3,2%-%time:~6,2%^
&%XCOPY% @file %backdir%\%itdate%D\worlds\@file^"

edited Nov 18, 2014 at 14:47

answered Apr 27, 2014 at 18:19

dbenham

132k29 gold badges273 silver badges410 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Brandon Over a year ago

"Copying Worlds:" ERROR: Invalid argument/option - '@file'. Type "FORFILES /?" for usage. Invalid switch - /q" @file backup\2014-04-28D\worlds\@file" "Copying Plugins" That does not seem to work, I tried your method before going to the method described by the For loop, they both seem to not work.

dbenham Over a year ago

@MegaSniperB - Whoops - I talked about the needed CMD /C in my text, then forgot to use it in my code. It should be fixed now.

joe P · Accepted Answer · 2016-04-21 14:58:32Z

6

I realize this is an old post, but another way of doing it is to call a batch file and pass it the parameters that it needs. And I do not believe that there is any limitations in what can be in that batch file. For example:

forfiles /M "*.img" /C "cmd /c ProcessFile.bat @file @fdate @ftime"

answered Apr 21, 2016 at 14:58

joe P

611 silver badge1 bronze badge

1 Comment

Kelly Bang Over a year ago

Assuming your initial batch file doesn't have any parameters, you can call itself and use "IF EXIST %1 GOTO LABEL"

Collectives™ on Stack Overflow

How to use multiple commands in batch using forfiles command?

2 Answers 2

2 Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related