Trouble Inserting an element into xml using XSLT 2.0

Question

I am receiving a soap message(XML) and after adding a new XML element i have to send it further to another service. Is it possible to add the element by using XSLT 2.0. If so then how?

Input Message

<?xml version="1.0" encoding="utf-8"?>
<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
  <soapenv:Body>
    <tns:GLBookingMessage xmlns:tns="http://com.example/cdm/finance/generalledger/v1"> 
      <tns:GLBooking> 

      </tns:GLBooking>
    </tns:GLBookingMessage>
  </soapenv:Body>
</soapenv:Envelope>

Required Output Message:

<?xml version="1.0" encoding="utf-8"?>
<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
  <soapenv:Body>

    <tns:GLBookingMessage xmlns:tns="http://com.example/cdm/finance/generalledger/v1"> 
      <CHeader>
      </CHeader>    
      <tns:GLBooking> 

      </tns:GLBooking>
    </tns:GLBookingMessage>
  </soapenv:Body>
</soapenv:Envelope>

XSLT Sheet:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 

  xmlns:cdm="http://com.example//cdm/finance/generalledger/v1" 
  xmlns:tns="http://com.example//cdm/finance/generalledger/v1" 
  xmlns:cur="http://com.example//cdm/currencycodes/v1"
  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" 
>

  <xsl:output method="xml" encoding="utf-8" indent="yes"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy> 
  </xsl:template>
  <xsl:template match="//GLBookingMessage">
    <GLBookingMessage>
      <xsl:copy-of select="."/> 
      <CHeader>

      </CHeader>
    </GLBookingMessage> 
  </xsl:template>

</xsl:stylesheet>

It is quite simple.. Did you try something?

Linga Murthy C S
– Linga Murthy C S

2014-11-13 11:06:35 +00:00
Commented Nov 13, 2014 at 11:06 — Linga Murthy C S
– Linga Murthy C S, Commented Nov 13, 2014 at 11:06
i have added my XSLT sheet in the question.

omer khalid
– omer khalid

2014-11-13 11:21:54 +00:00
Commented Nov 13, 2014 at 11:21 — omer khalid
– omer khalid, Commented Nov 13, 2014 at 11:21

Linga Murthy C S · Accepted Answer · 2014-11-13 11:45:14Z

1

Try this: The first template copies all the attributes and nodes as it is. Since the tns:GLBookingMessage element is the one that needs change, we have a template for that(this template gets precedence over the first template), in which we use xsl:copy to create the tag(tns:GLBookingMessage), apply-templates for attributes(to copy attributes, not required in your case). Then, add the new element CHeader and the again apply-templates for all the nodes(), which is going to call the first template, thereby copying all the children of tns:GLBookingMessage as they are..

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tns="http://com.example/cdm/finance/generalledger/v1">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="tns:GLBookingMessage">
    <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <CHeader/>
        <xsl:apply-templates select="node()"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Your namespaces in XSLT aren't matching in your Input XML.. after correcting these, you could have moved <CHeader/> above copy-of and by changing the copy-of to

<xsl:copy-of select="*"/>

But my answer makes good use of the identity template(the first template) for copying..

edited Nov 13, 2014 at 11:45

answered Nov 13, 2014 at 11:22

Linga Murthy C S

5,4323 gold badges15 silver badges22 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

omer khalid Over a year ago

Thanks alot it works. Can u just explain in 1 to 2 lines how it is working.

Collectives™ on Stack Overflow

Trouble Inserting an element into xml using XSLT 2.0

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related