Remove Duplicate Value from 2D Array in Vbscript

Assuming you

1. insist on using a rectangular array
2. can live with Empty cells
3. mean "unique per row/column"

you can use a dictionary and move the unique elements to the left/top:

  Dim a(1, 4)
  a(0,0)="Volvo"
  a(0,1)="BMW"
  a(0,2)="Ford"
  a(0,3)="Ford"
  a(0,4)="Ford"
  a(1,0)="Apple"
  a(1,1)="Orange"
  a(1,2)="Banana"
  a(1,3)="Orange"
  WScript.Echo "Before:"
  disp2DA a
  uniq2DA a
  WScript.Echo "After:"
  disp2DA a

Sub uniq2DA(a)
  Dim d : Set d = CreateObject("Scripting.Dictionary")
  Dim i, j, k
  For i = 0 To UBound(a, 1)
      d.RemoveAll
      k = 0
      For j = 0 To UBound(a, 2)
          If Not d.Exists(a(i, j)) Then
             d(a(i, j)) = Empty
             a(i, k) = a(i, j)
             k = k + 1
          End If
      Next
      For j = k To UBound(a, 2)
          a(i, j) = Empty
      Next
  Next
End Sub

Sub disp2DA(a)
  Dim i, j, s
  For i = 0 To UBound(a, 1)
      For j = 0 To UBound(a, 2)
          If IsEmpty(a(i,j)) Then s = " <Empty>" Else s = " " & a(i, j)
          WScript.StdOut.Write s
      Next
      WScript.Echo
  Next
End Sub

output:

Before:
 Volvo BMW Ford Ford Ford
 Apple Orange Banana Orange <Empty>
After:
 Volvo BMW Ford <Empty> <Empty>
 Apple Orange Banana <Empty> <Empty>

If you are willing to use a ragged array, you can use the uniqFE() function from here:

  Dim a : a = Array( _
       Split("Volvo BMW Ford Ford Ford") _
     , Split("Apple Orange Banana Orange Pear") _
  )
  WScript.Echo "Before:"
  disp2DAoA a
  Dim i
  For i = 0 To UBound(a)
      a(i) = uniqFE(a(i))
  Next
  WScript.Echo "After:"
  disp2DAoA a

Sub disp2DAoA(a)
  Dim e
  For Each e In a
      WScript.Echo Join(e)
  Next
End Sub

' returns an array of the unique items in for-each-able collection fex
Function uniqFE(fex)
  Dim dicTemp : Set dicTemp = CreateObject("Scripting.Dictionary")
  Dim xItem
  For Each xItem In fex
      dicTemp(xItem) = 0
  Next
  uniqFE = dicTemp.Keys()
End Function

output:

Before:
Volvo BMW Ford Ford Ford
Apple Orange Banana Orange Pear
After:
Volvo BMW Ford
Apple Orange Banana Pear