Using output from a PowerShell command in a windows batch file

Question

I have a path in variable (script parameter) %2. I need to do the following:

Extract the leaf (last folder from the path) to a variable.
Run the following command: robocopy %2 \\somepath\%leaf

I was told this could be done in PowerShell (cause I've tried going with batch file alone and failed miserably) Here's a pseudocode representation of what I'd like to achieve:

set leaf = powershell -command (split-path %2 -leaf)
robocopy %2 \\somepath\%leaf

Any idea how to write this correctly? Thank you.

Can you give me an example with some mock folder names? I'm having a hard time following you with your usage of %2. Batch scripting is not a strength of mine, while PowerShell is. — FoxDeploy
– FoxDeploy, Commented Feb 5, 2015 at 14:41
I'm sorry but that would be of no use to me. Just like you, I can code in PowerShell, not Batch. I need to write the the batch command so that it'll work in my batch script, with the %2 and all. — Shaggydog
– Shaggydog, Commented Feb 5, 2015 at 14:53
any reason why you can't run robocopy from within powershell. In theory you could use batch FOR statement to get the output from powershell but why?? e.g. $leaf = (split-path %2 -leaf); robocopy %2 \somepath\$leaf — Stephen Connolly
– Stephen Connolly, Commented Feb 5, 2015 at 14:55

rojo · Accepted Answer · 2015-02-05 15:01:31Z

2

Whenever you want to set a batch variable to the output of a command, use for /f. Here's an example:

@echo off
setlocal

set "psCommand=powershell -command "(split-path '%~2' -leaf)""
for /f "delims=" %%I in ('%psCommand%') do set "leaf=%%I"

echo %leaf%

But this is a terribly inefficient way to retrieve the last folder of a path. Instead of invoking PowerShell, what you should do is this:

@echo off
setlocal

for %%I in ("%~2") do set "leaf=%%~nxI"

echo %leaf%

The %%~dpnxI notation gets

d = drive
p = path
n = name
x = extension

It's traditionally intended for files, rather than directories; but it works just as well for directories anyway. See the last couple of pages of for /? in a console window for complete details.

edited Feb 5, 2015 at 15:01

answered Feb 5, 2015 at 14:55

rojo

24.5k5 gold badges61 silver badges104 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Shaggydog Over a year ago

Thanks, that finally worked (the second option). I have no idea how or why it works, and I've been battling with this for hours. Also, in your first example, why is robocopy part of the powershell command?

rojo Over a year ago

@Shaggydog Your question was originally formatted with robocopy on the same line as split-path. I didn't pay close enough attention to whether that was valid PowerShell-ese or not. Edited.

Magoo · Accepted Answer · 2015-02-05 14:59:06Z

0

FOR %%a IN ("%~2") DO FOR %%b IN ("%%~dpa.") DO ECHO %%~nxb

Batch one-liner. Take the parameter (second parameter here), remove any quotes and re-apply them. Select the drive and path, add '.' then select the name and extension of the result making leaf required.

Obviously, if you require this in a variable,

FOR %%a IN ("%~2") DO FOR %%b IN ("%%~dpa.") DO set "leaf=%%~nxb"

answered Feb 5, 2015 at 14:59

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Collectives™ on Stack Overflow

Using output from a PowerShell command in a windows batch file

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related