Remove first part of the string by batch command

Question

This is my full path U:\temp\Obj\x64\Debug\XUIBaseHelp\XUIBaseHelp.def

I need to get the \x64\Debug\XUIBaseHelp\XUIBaseHelp.def part from this by removing first part.

Any idea?

Anders Lindahl · Accepted Answer · 2015-06-12 08:30:09Z

3

If it is always U:\temp\Obj that needs to be removed, a simple string edit/replace will do:

C:\>set FOO=U:\temp\Obj\x64\Debug\XUIBaseHelp\XUIBaseHelp.def
C:\>set BAR=%FOO:U:\temp\Obj=%
C:\>echo %BAR%
\x64\Debug\XUIBaseHelp\XUIBaseHelp.def

answered Jun 12, 2015 at 8:30

Anders Lindahl

43.3k9 gold badges93 silver badges94 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Nayana Adassuriya Over a year ago

is there a way to use U:\temp\Obj part inside a variable?

MC ND · Accepted Answer · 2015-06-12 08:46:57Z

3

There are several ways to do it depending on what the final requirements are. While the result will be the same, it is not the same to remove two folders from the start than to search three folders up. Some samples

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "value=U:\temp\Obj\x64\Debug\XUIBaseHelp\XUIBaseHelp.def"

    rem Tokenize and remove elements from the start
    set "newValue="
    for /f "tokens=3,* delims=\:" %%a in ("%value%") do set "newValue=\%%b"
    echo %newValue%

    rem Going backward from the end
    set "newValue="    
    for %%a in ("%value%\..\..\..\..") do set "newValue=%%~fa"
    setlocal enabledelayedexpansion & for /f "delims=" %%a in ("!value:%newValue%=!") do (endlocal & set "newValue=%%a")
    echo %newValue%

    rem Discarding known elements at the start
    set "newValue=\x64%value:*x64=%"
    echo %newValue%

    set "newValue=%value:*\Obj\=\%"
    echo %newValue%

answered Jun 12, 2015 at 8:46

MC ND

71.1k8 gold badges95 silver badges136 bronze badges

2 Comments

Nayana Adassuriya Over a year ago

I'm using your last option. how to remove the first back shahs also? So final will be x64\Debug\XUIBaseHelp\XUIBaseHelp.def

MC ND Over a year ago

@NayanaAdassuriya, the code is replacing everything up to \Obj\ with a backslash, so, remove the backslash set "newValue=%value:*\Obj\=%"

Collectives™ on Stack Overflow

Remove first part of the string by batch command

2 Answers 2

1 Comment

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related