In a batch file, combining two strings to create a combined path string

Question

I need to take two strings and combine them into a single path string inside a batch file similar to the Path.Combine method in .NET. For example, whether the strings are "C:\trunk" and "ProjectName\Project.txt" or "C:\trunk\" and "ProjectName\Project.txt", the combined path will be "C:\trunk\ProjectName\Project.txt".

I have tried using PowerShell's join-path command which works, but I need a way to pass this value back to the batch file. I tried using environment variables for that, but I wasn't successful. One option for me is to move all that code into a PowerShell script and avoid the batch file altogether. However, if I had to do it within the batch file, how would I do it?

Joey · Accepted Answer · 2012-09-24 15:28:11Z

16

Environment variables you set in a subprocess cannot be passed to the calling process. A process' environment is a copy of its parent's but not vice versa. However, you can simply output the result in PowerShell and read that output from the batch file:

for /f "delims=" %%x in ('powershell -file foo.ps1') do set joinedpath=%%x

Still, since PowerShell needs about a second to start this may not be optimal. You can certainly do it in a batch file with the following little subroutine:

:joinpath
set Path1=%~1
set Path2=%~2
if {%Path1:~-1,1%}=={\} (set Result=%Path1%%Path2%) else (set Result=%Path1%\%Path2%)
goto :eof

This simply looks at the very last character of the first string and if it's not a backslash it will add one between the two – pretty simple, actually.

Sample output:

JoinPath "C:\trunk" "ProjectName\Project.txt"
-- C:\trunk\ProjectName\Project.txt
JoinPath "C:\trunk\" "ProjectName\Project.txt"
-- C:\trunk\ProjectName\Project.txt

The code and sample batch file can be found in my SVN but are reproduced here since they're quite brief anyway:

@echo off
echo JoinPath "C:\trunk" "ProjectName\Project.txt"
call :joinpath "C:\trunk" "ProjectName\Project.txt"
echo -- %Result%

echo JoinPath "C:\trunk\" "ProjectName\Project.txt"
call :joinpath "C:\trunk\" "ProjectName\Project.txt"
echo -- %Result%

goto :eof

:joinpath
set Path1=%~1
set Path2=%~2
if {%Path1:~-1,1%}=={\} (set Result=%Path1%%Path2%) else (set Result=%Path1%\%Path2%)
goto :eof

edited Sep 24, 2012 at 15:28

answered Jun 24, 2010 at 22:04

Joey

357k88 gold badges705 silver badges700 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Martin Beckett Over a year ago

What if one path contains spaces and is quoted? Do you end up with "c:\trunk space"\project.txt instead of "c:\trunk space\project.txt"

Joey Over a year ago

@Martin: Just try it out, that's why the code is there. And no, you don't. I'm using %~1 and %~2 in that subroutine which will strip the quotes around the argument. Of course, you need to quote yourself properly, but that's always the case (e.g. when iterating over files with for).

kiss my armpit Over a year ago

How can I download your sample batch?

Joey Over a year ago

There seems to be a configuration issue. I'll poke my hoster later; for now I have reproduced the code in the answer. It doesn't contain much more.

Collectives™ on Stack Overflow

In a batch file, combining two strings to create a combined path string

1 Answer 1

4 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related