Error while assigning XML attribute value in XSLT

Question

My input XML is as below:

<MessageOutput Status="2">
    <Source>External</Source>
    <Error>Server not reachable</Error>
    <LineNo>0</LineNo>
</MessageOutput>

My requirement is to write XSLT and check if <Error> tag has value "Server not reachable" and if yes then change the Status attribute value to "3".

I wrote below code but getting error:

"XSLT Error: Open quote is expected for attribute "{1}" associated with an element type "Status"."

Please assist.

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" encoding="ISO-8859-1"/>

    <xsl:variable name="Des" select="'Server not reachable'"/>
    <xsl:variable name="Err" select="MessageOutput/Error"/>

    <xsl:template match="*">
        <xsl:copy>
        <xsl:copy-of select="@*" />
        <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/MessageOutput">
        <xsl:choose>
            <xsl:when test="$Des=$Err">
                <MessageOutput Status="3">
                    <xsl:apply-templates/>
                </MessageOutput>
             </xsl:when>
             <xsl:otherwise>
                <MessageOutput Status=<xsl:value-of select="@Status"/>>
                    <xsl:apply-templates/>
                </MessageOutput>
             </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

sergdenisov · Accepted Answer · 2015-07-05 19:39:58Z

2

Try this:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" encoding="ISO-8859-1"/>

    <xsl:variable name="Des" select="'Server not reachable'"/>
    <xsl:variable name="Err" select="MessageOutput/Error"/>

    <xsl:template match="*">
        <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/MessageOutput">
        <xsl:choose>
            <xsl:when test="$Des=$Err">
                <MessageOutput Status="3">
                    <xsl:apply-templates/>
                </MessageOutput>
             </xsl:when>
             <xsl:otherwise>
                <MessageResult Status="{@Status}">
                    <xsl:apply-templates/>
                </MessageResult>
             </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

edited Jul 5, 2015 at 19:39

answered Jul 5, 2015 at 19:21

sergdenisov

8,6129 gold badges52 silver badges67 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

HelloFriends Over a year ago

Done. Once again Thanks a lot.

michael.hor257k · Accepted Answer · 2015-07-05 20:02:28Z

1

Or shortly:

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="MessageOutput[Error='Server not reachable']/@Status">
    <xsl:attribute name="Status">3</xsl:attribute>
</xsl:template>

</xsl:stylesheet>

answered Jul 5, 2015 at 20:02

michael.hor257k

118k6 gold badges36 silver badges55 bronze badges

Collectives™ on Stack Overflow

Error while assigning XML attribute value in XSLT

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related