gnuplot - conditional colors in a points plot

Question

I have the following data:

ClockIndex       Max AvgStd  Avg      Num    Threshold
"ck1 (1.54 GHz)" 35  +16.30   11    11583    X
"ck2 (1.54 GHz)" 28  +16.66   12    10669    -
"ck3 (1.54 GHz)" 29  +14.47    9     8036    -
"ck4 (1.54 GHz)" 35  +18.99   12     5685    -
"ck5 (1.54 GHz)" 9   +6.04     3       11    -

I'm plotting columns 2, 3, 4 together in a points plot, one line per entry.

Using this code:

set xtics rotate
set xlabel ""
set ylabel "Levels"
set title "Levels - foo"
set key autotitle columnhead
set term png medium size 1200,600
set grid
set output "foo.png"
plot "foo.rpt" using 2:xticlabels(1) with points pt 13 ps 2 lt rgb "blue",\
"" using 3:xticlabels(1) with points pt 13 ps 2 lt rgb "red",\
"" using 4:xticlabels(1) with points pt 13 ps 2 lt rgb "black

**Goal : If there's a "X" in the "Threshold" column, I want the "Max" point to be green, not blue.

I've tried using awk, but to no avail.

plot "< awk '{if($6 == \"X\") print }' foo.rpt" using 2:xticlabels(1) with points pt 13 ps 2 lt rgb "blue",\
"" using 3:xticlabels(1) with points pt 13 ps 2 lt rgb "red",\
"" using 4:xticlabels(1) with points pt 13 ps 2 lt rgb "black"
"< awk '{if($6 == \"-\") print }' foo.rpt" using 2:xticlabels(1) with points pt 13 ps 2 lt rgb "green",\
"" using 3:xticlabels(1) with points pt 13 ps 2 lt rgb "red",\
"" using 4:xticlabels(1) with points pt 13 ps 2 lt rgb "black"

I keep getting errors like:

"foo_gnuplot", line 11: warning: Skipping data file with no valid points

Any help would be greatly appreciated! Thanks much for taking a look! :)

havogt · Accepted Answer · 2015-07-24 09:19:18Z

2

You can do it like this:

plot "foo.rpt" using 2:xticlabels(1) with points pt 13 ps 2 lt rgb "blue",\
"" using 3:xticlabels(1) with points pt 13 ps 2 lt rgb "red",\
"" using 4:xticlabels(1) with points pt 13 ps 2 lt rgb "black",\
"" using (strcol(6) eq "X" )?($2):(1/0):xticlabels(1) with points pt 13 ps 2 lt rgb "green"

(condition)?($plotThisValue):(1/0) is a common gnuplot technique for conditional plotting.

With that code the original point is overprinted with the green one. (If you want to remove the original (now hidden) blue point completely you can use the same technique in line one of your plot command.)

answered Jul 24, 2015 at 9:19

havogt

2,8501 gold badge31 silver badges37 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

user5150183 Over a year ago

Thanks much, I appreciate the help!

user5150183 Over a year ago

Hi havogt ... I forgot to add the 6th column in my data set. It worked after doing that. Thanks again!

user5150183 · Accepted Answer · 2015-07-24 18:35:08Z

0

Thanks much to havogt for the great answer! Here's what I ended up doing:

plot "foo.rpt" using 3:xticlabels(1) with points pt 13 ps 2 lt rgb "red",\
"" using 4:xticlabels(1) with points pt 13 ps 2 lt rgb "black",\
"" using (strcol(6) eq "X" )?($2):(1/0):xticlabels(1) with points pt 13 ps 2 lt rgb "green"
"" using (strcol(6) eq "-" )?($2):(1/0):xticlabels(1) with points pt 13 ps 2 lt rgb "blue"

Works great! Really appreciate the help!

answered Jul 24, 2015 at 18:35

user5150183

113 bronze badges

Collectives™ on Stack Overflow

gnuplot - conditional colors in a points plot

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related