Getting multiple index values from an array

Compiled and running perfectly:

Module Module1

    Sub Main()

        Test("Leniel")

    End Sub
    Sub Test(ByVal text As String)

        Dim alphabet() As String = {"a", "b", "c", "d", "e",
                                    "f", "g", "h", "i", "j",
                                    "k", "l", "m", "n", "o",
                                    "p", "q", "r", "s", "t",
                                    "u", "v", "w", "x", "y", "z"}

        Dim indexes = From letter In text.ToCharArray() _
            Select Array.IndexOf(alphabet, letter.ToString().ToLower())

        Dim i As Integer
        For Each i In indexes
            MsgBox(i)
        Next

    End Sub

End Module

It will show in the message box respectively:

'l   e  n   i  e  l
 11, 4, 13, 8, 4, 11

I will "attack" that problem using a dictionary rather than an array. Each letter of the alphabet is a key with value corresponding to an index.

I don't think is a good idea creating the alphabet every time a call is made. Define the alphabet only once and use it as much as needed.

Module Module1

    'Byte datatype is suffice for this example.
    Dim Alphabet As Dictionary(Of String, Byte)

    Sub Main()

        Alphabet = New Dictionary(Of String, Byte)

        'Dim letters(25) As String
        'letters(0) = "a" : letters(1) = "b" : letters(2) = "c"
        'letters(3) = "d" : letters(4) = "e" : letters(5) = "f"
        'letters(6) = "g" : letters(7) = "h" : letters(8) = "i"
        'letters(9) = "j" : letters(10) = "k" : letters(11) = "l"
        'letters(12) = "m" : letters(13) = "n" : letters(14) = "o"
        'letters(15) = "p" : letters(16) = "q" : letters(17) = "r"
        'letters(18) = "s" : letters(19) = "t" : letters(20) = "u"
        'letters(21) = "v" : letters(22) = "w" : letters(23) = "x"
        'letters(24) = "y" : letters(25) = "z"
        'GenerateAlphabet(letters)

        'Or define alphabet like this
        Dim letters As String = "a b c d e f g h i j k l m n o p q r s t u v w x y z æ ø å"
        GenerateAlphabet(letters)

        'Generating a couple of ways to test
        Dim words1 As New List(Of String) From {
            "Hello",
            "World",
            "I",
            "somehow",
            "exist"
        }
        Dim sentence As String = "Hello World I somehow exist"
        'Dim words2 As String() = {"Hello", "World", ""}'This will throw exception on the last word
        'Dim oneWord As String() = {"ThisIsOneWord!"} 'This will throw exception on the last char

        Try
            Testing(words1)
            Testing(sentence)
            'Testing(words2)
            'Testing(oneWord)
        Catch ex As Exception
            Console.WriteLine(ex.Message)
        End Try

        Console.ReadKey()
    End Sub

    Private Sub GenerateAlphabet(alphabet_chars As ICollection(Of String))
        Populate(alphabet_chars)
    End Sub

    Private Sub GenerateAlphabet(alphabet_chars As String)
        Populate(alphabet_chars.Split({" "c}, StringSplitOptions.RemoveEmptyEntries))
    End Sub

    Public Sub Testing(words As ICollection(Of String))
        If words IsNot Nothing AndAlso words.Count <> 0 Then
            For i = 0 To words.Count - 1
                Console.WriteLine(String.Join(" ", GetIndices(words(i).ToLower())))
            Next
        Else
            Throw New ArgumentException($"'{NameOf(words)}' cannot be null or empty.", NameOf(words))
        End If
    End Sub

    Public Sub Testing(sentence As String)
        If sentence IsNot Nothing AndAlso sentence <> String.Empty AndAlso sentence.Length <> 0 Then
            Dim words = sentence.Split({" "c}, StringSplitOptions.RemoveEmptyEntries)
            For i = 0 To words.Count - 1
                Console.WriteLine(String.Join(" ", GetIndices(words(i).ToLower())))
            Next
        Else
            Throw New ArgumentException($"'{NameOf(sentence)}' cannot be null or empty.", NameOf(sentence))
        End If
    End Sub

    Private Sub Populate(letters As ICollection(Of String))
        Dim indx As Byte
        For Each letter In letters
            Alphabet.Add(letter.ToLower(), indx)
            'remove cast if indx is of type int32 and (indx +=1 can be used.)
            indx = CByte(indx + 1)
        Next
    End Sub

    Private Function GetIndices(word As String) As IEnumerable(Of Byte)

        If String.IsNullOrEmpty(word) OrElse String.IsNullOrWhiteSpace(word) Then
            Throw New ArgumentException($"'{NameOf(word)}' cannot be null, empty or whitespace.", NameOf(word))
        End If

        Dim retValue(word.Length - 1) As Byte
        Dim currChar As Char 'current char

        For i = 0 To word.Length - 1
            currChar = word(i)
            If Alphabet.ContainsKey(currChar) Then
                retValue(i) = Alphabet(word(i))
            Else
                Throw New Exception($"An invalid char was found. [{currChar}] is not part of the defined alphabet.")
            End If
        Next

        Return retValue
    End Function

End Module

There are a million ways to approach this.

One solution:

1) Get the text

Dim theText = TextBox2.Text

2) For each letter in that text, get the number (and display it as a message

Dim c As Char
For Each c In theText
   MsgBox(translateCharacter(c))
Next

Public Function translateCharacter(ByVal c As Char) As Integer
    translateCharacter = abc.Where(Function(a) a.Contains(c)).Select(Function(s) Array.IndexOf(abc, s)).ToArray()
End Function

Provided that compiles, it should pop up each number, one by one. I used the same function you were using to translate the character (i.e. get the result). There are other ways to do this, I just wanted to address your main question by point out that you can iterate over all the characters in the string.

I hope that helps,

--gMale

The first thing that comes to mind is to use the .split method on the textbox input to get an array of characters. Perform your search on each element in the array, adding each match to the result array.