Generate function definition with template haskell

Question

How to write a template Haskell function such that:

mkFunc "func"

generates

func = "func"

I've tried this

mkFunc x = ValD (VarP x) (NormalB (LitE (StringL x))) []

But it doesn't typecheck:

Couldn't match type ‘Name’ with ‘[Char]’
Expected type: String
  Actual type: Name
In the first argument of ‘StringL’, namely ‘x’
In the first argument of ‘LitE’, namely ‘(StringL x)’

Also, after defining mkFunc, how can I define mkFuncs which makes a list of function definitions?

Sibi · Accepted Answer · 2015-08-30 03:21:46Z

4

You can get help using runQ and see what abstract syntax tree it produces:

λ> runQ [d|func = "func"|]
[ValD (VarP func_4) (NormalB (LitE (StringL "func"))) []]

And then you can just translate that into code:

-- External.hs
{-#LANGUAGE TemplateHaskell#-}

module External where

import Language.Haskell.TH

mkFunc :: String -> Q [Dec]
mkFunc str = return [ValD (VarP str') (NormalB (LitE (StringL str))) []]
    where str' = mkName str

And the other module:

-- Other.hs
{-#LANGUAGE TemplateHaskell#-}
import External

$(mkFunc "haskell")

main = print haskell

Demo in ghci:

λ> main
"haskell"

And creating mkFuncs is straightforward from this:

mkFuncs :: [String] -> Q [Dec]
mkFuncs srt = return decs
    where dec n s = ValD (VarP n) (NormalB (LitE (StringL s))) []
          srt' = map (\x -> (mkName x, x)) srt
          decs = map (\(n,s) -> dec n s) srt'

edited Aug 30, 2015 at 3:21

answered Aug 29, 2015 at 23:20

Sibi

49k18 gold badges105 silver badges172 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

doofin Over a year ago

thanks! a little more refined: makeFuncs::[String]->Q [Dec] makeFuncs ss=return $ foldl1 (++) $ mapM (\x->[ValD (VarP (mkName x)) (NormalB (LitE (StringL x))) []]) ss btw, can we use quasiquoters instead of manipulating AST directly?

Collectives™ on Stack Overflow

Generate function definition with template haskell

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related