Push array to a certain hash within an array in Perl

Question

I want to dynamically push values of hashes into an array of hashes in Perl.

I have this code block to create and push classHash to an array classList.

    $courseName = <STDIN>;
    $section = <STDIN>;

    my $classHash = {};

    $classHash->{courseName} = $courseName;
    $classHash->{section} = $section;
    push @classList, $classHash;

Now, I want to add a studentHash to the classHash.

    for my $i ( 0 .. $#classList ) {
        #I want to add the studentHash to a specific classHash in the classList
        if($courseName1 eq $classList[$i]{courseName} && $section1 eq $classList[$i]{section}){
             $studName = <STDIN>;
             $studNum = <STDIN>;

             my $studHash = {};

             $studHash->{studName} = $studName;
             $studHash->{studNum} = $studNum;

             push @studList, $studHash;
             push @{$classList[$i]}, \@studList; #but this creates an array reference error
        }
    }

Add $classHash->{students} = []; and then push your $studHash into @{ $classList[$i]->{students} } — xxfelixxx
– xxfelixxx, Commented Sep 2, 2015 at 23:39
The studList array shall only be stored in an existing classHash (which was created on the first block of code). I don't get why I should add classHash->{students} = []; — skyranch
– skyranch, Commented Sep 2, 2015 at 23:46
Yes, so you can make room for the students by adding a students field to your %classHash, and then add the $studHash to that array. — xxfelixxx
– xxfelixxx, Commented Sep 2, 2015 at 23:51
maybe provide an example of the data structure you want to have in the end — xxfelixxx
– xxfelixxx, Commented Sep 2, 2015 at 23:53
It doesn't cause an error anymore, but what it does is add the studHash to all existing classHash. I want to add a studHash to a specific classHash only. — skyranch
– skyranch, Commented Sep 2, 2015 at 23:59

xxfelixxx · Accepted Answer · 2015-09-03 01:19:38Z

Ignoring the interactive bits... here is how you can add the student to the class:

#!/usr/bin/env perl

use warnings;
use strict;

use Data::Dumper;

my @classList = (
    {
       courseName => 'Algebra',
       section    => 101,
       students   => [],
    },
    {
       courseName => 'Geometry',
       section    => 102,
       students   => [],
    }, 
 );

my $studName = 'Alice';
my $studNum  = 13579;
my $desiredClass = 'Geometry';
my $desiredSection = 102;

for my $class (@classList) {
    if ($class->{courseName} eq $desiredClass and
        $class->{section}    eq $desiredSection) {
        # Add student to the class
        my $student = {
            studName => $studName,
            studNum  => $studNum,
        };
        push @{ $class->{students} }, $student;
    }
}

print Dumper \@classList;

# Printing out the students for each class
for my $class (@classList) {
    my $course  = $class->{courseName};
    my $section = $class->{courseSection};
    my $students = $class->{students};
    my $total_students = scalar @$students;
    my $names = join ', ', map { $_->{studName} } @$students;

    print "There are $total_students taking $course section $section.\n";
    print "There names are [ $names ]\n";
}

Output

VAR1 = [
      {
        'students' => [],
        'section' => 101,
        'courseName' => 'Algebra'
      },
      {
        'students' => [
                        {
                          'studNum' => 13579,
                          'studName' => 'Alice'
                        }
                      ],
        'section' => 102,
        'courseName' => 'Geometry'
      }
    ];

There are 0 students taking Algebra section 101.
There names are [ ]
There are 1 students taking Geometry section 102.
There names are [ Alice ]

How to access each students in a class? The code works but I don't know how to print the studList per classHash

Collectives™ on Stack Overflow

Push array to a certain hash within an array in Perl

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related