Get json config value into windows script variable

Question

I would like to parse config.json file and gets some specific values into variables.

Following command is working, it print value from json: type config.json | "jq-win64.exe" .path.editor

config.json content: { "path" : { "editor" : "...value..." } }
jq is library for json (https://stedolan.github.io/jq/)

Question is how to get this value into some variable ?

I tried this, but is not working: set editorPath = type config.json | "jq-win64.exe" -r .path.editor

Result is that %editorPath% is empty

Maybe it's related to jq library (https://stedolan.github.io/jq/) but I am quite noob in windows shell so maybe someone can help how to solve this issue.

Thanks

You might find this answer useful. Since your JSON is formatted properly, remove the braces from the eval line, and echo editor: !editor! — rojo
– rojo, Commented Sep 15, 2015 at 11:57
In general, when you want to capture the output of a command to a variable, use a for /F loop. for /f "delims=" %%I in ('command') do set "variable=%%I" or similar. See help for in a cmd console for more info. — rojo
– rojo, Commented Sep 15, 2015 at 12:00

Community · Accepted Answer · 2017-05-23 12:25:07Z

2

In general, when you want to capture the output of a command to a variable, use a for /F loop. for /f "delims=" %%I in ('command') do set "variable=%%I" or similar. See help for in a cmd console for more info.

It is possible to make JScript interpret JSON similar to the way JavaScript would. There are security concerns; but if you can be reasonably certain no one is likely to insert malicious code into the JSON, you can parse it without requiring 3rd party tools.

This example script combines the two ideas mentioned above -- invoking a JScript code block with cscript.exe, and capturing its output with a for /f loop.

config.json:

{ "path" : { "editor" : "...value..." } }

parseJSON.bat:

@if (@CodeSection == @Batch) @then

@echo off
setlocal

set "JSONfile=config.json"

for /f "delims=" %%I in ('cscript /nologo /e:JScript "%~f0" "%JSONfile%"') do set "%%~I"

rem // Delayed expansion prevents path names with symbols (& or %) from choking the script
setlocal enabledelayedexpansion
echo editor: !editor!
endlocal

goto :EOF

@end // end batch / begin JScript chimera

var fso = WSH.CreateObject('scripting.filesystemobject'),
    JSONfile = fso.OpenTextFile(WSH.Arguments(0), 1);

eval('obj = ' + JSONfile.ReadAll());
JSONfile.Close();

function walk(tree) {
    for (var i in tree) {
        if (typeof tree[i] === 'object') walk(tree[i]);
        else WSH.Echo(i + '=' + tree[i]);
    }
}

walk(obj);

Output:

editor: ...value...

edited May 23, 2017 at 12:25

CommunityBot

11 silver badge

answered Sep 15, 2015 at 12:17

rojo

24.5k5 gold badges61 silver badges104 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Jurosh Over a year ago

Thanks this helped me to quite understand issue.. Now I have something like: for /f "delims=" %%I in ('readConfig .path.to.something') do set PathToSomething=%%I and it seem to be doing what I needed. readConfig is only doing output of jq commands...

peak · Accepted Answer · 2015-09-15 14:56:08Z

0

Here are illustrations of two approaches using jq:

@echo off
setlocal

for /f "delims=" %%I in ('jq -n -r "\"123\""') do set A=%%I
echo A is %A%

jq -n -r  "@sh \"set B=123\"" > setvars.bat
call .\setvars.bat
echo B is %B%

In the first example, the batch file determines the variable name; in the second example, the jq program determines the variable name(s).

By the way, for non-Windows users, there is a "recipe" about this in the jq Cookbook.

answered Sep 15, 2015 at 14:56

peak

119k21 gold badges185 silver badges218 bronze badges

Collectives™ on Stack Overflow

Get json config value into windows script variable

2 Answers 2

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related