nested for loop - Processing (java)

Question

my task is to draw a grid of 10 x 10 wheels. Each should be a random color and have lots of spokes like a real wheel. I have to do this using nested for loops.

I have got to the code below but for some reason its drawing a 10 x infinite grid. I don't understand why as the outer loop should only run 10 times.

float XPos = 25;
float YPos = 25;
float Radius = 20;

void setup() {
    size(500, 500);
}

void draw() {
    for (int h = 0; h < 10; h++) {
        for (int i = 0; i < 10; i++) {
            float RanR = random(250);
            float RanG = random(250);
            float RanB = random(250);

            stroke(RanR, RanG, RanB);
            ellipse(XPos, YPos, Radius * 2, Radius * 2);

            for (int j = 0; j < 360; j += 10) {
                stroke(RanR, RanG, RanB);
                line(XPos, 
                     YPos, 
                     XPos + Radius * sin(radians(j)), 
                     YPos + Radius * cos(radians(j))
                    );
            }

            XPos += Radius * 2;
        }

        XPos = 25;
        YPos += Radius * 2;
    }
}

You have to show what does these methods stroke and line do? Also you have three nested fors so in a simple math you have 10*10*36 (360/10) — Jorge Campos
– Jorge Campos, Commented Oct 13, 2015 at 16:40
yes stroke determines the color of the lines. line draws the line. the inner for loop repeats 36 times to draw the spokes and when its finished it will move on to the next cirlce — Jason
– Jason, Commented Oct 13, 2015 at 16:42
I can't see why is printing infinite circles, maybe you should post all the code, but be careful, post only the code that you think be important — Johnny Willer
– Johnny Willer, Commented Oct 13, 2015 at 16:52
@JorgeCampos This is Processing, not strict Java. Those are not user-defined methods, but methods in the Processing API. — Kevin Workman
– Kevin Workman, Commented Oct 13, 2015 at 16:54
that is all the code, turns out the draw void was being done over and over which was making infinite rows — Jason
– Jason, Commented Oct 13, 2015 at 16:56

Kevin Workman · Accepted Answer · 2015-10-13 16:58:07Z

2

The draw() function is automatically called 60 times per second. You're saving your XPos and YPos variables outside of the draw() function, so any changes you make to them inside your draw() function will persist the next time draw() is called.

Instead of saving your XPos and YPos variables at the top-level of the sketch, you could create them inside your for loop and base them off of h and i:

float Radius = 20;

void setup() {
  size(500, 500);
}

void draw() {
  for (int h = 0; h < 10; h++) {
    for (int i = 0; i < 10; i++) {

      float XPos = 25+40*h;
      float YPos = 25+40*i;
      float RanR = random(250);
      float RanG = random(250);
      float RanB = random(250);

      stroke(RanR, RanG, RanB);
      ellipse(XPos, YPos, Radius * 2, Radius * 2);

      for (int j = 0; j < 360; j += 10) {
        stroke(RanR, RanG, RanB);
        line(XPos, 
        YPos, 
        XPos + Radius * sin(radians(j)), 
        YPos + Radius * cos(radians(j))
          );
      }
    }
  }
}

Notice that this will cause your circles to be redrawn in random colors 60 times per second. You could either use the randomSeed() function to get the same random numbers each time, or you could call noLoop() at the end of draw() so that it's not automatically called again.

answered Oct 13, 2015 at 16:58

Kevin Workman

42.3k12 gold badges72 silver badges110 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Jason Over a year ago

thanks that works too and is alot better. I would just have to remove the draw void so the code doesnt repeat

Kevin Workman Over a year ago

@Will That's probably not a very good idea. Use noLoop() instead.

Joop Eggen · Accepted Answer · 2015-10-13 16:55:32Z

0

Your code looks well, except that draw must be reentrant. That is, upon being called a second time it should start drawing at the same position.

So (apart from the Radius), the fields should be kept local to the draw method.

void draw() {
    float XPos = 25;
    float YPos = 25;
    float Radius = 20;

In real GUIs the draw or paint method is called whenever the screen must be updated.

My guess: draw is called more than once.

BTW. Java convention is to use an initial small letter for fields, local variables, and methods: xPos, yPos, radius.

edited Oct 13, 2015 at 16:55

answered Oct 13, 2015 at 16:52

Joop Eggen

110k8 gold badges89 silver badges142 bronze badges

4 Comments

Megh Vidani Over a year ago

how is it called multiple times? because of line or ellipse function calls?

Jason Over a year ago

thanks u got it, i took out the void setup and void draw so the code only runs once and it gave me a 10 x 10 grid. thank alot

Ingo Bürk Over a year ago

"Called directly after setup(), the draw() function continuously executes the lines of code contained inside its block until the program is stopped or noLoop() is called. " – processing.org/reference/draw_.html

Kevin Workman Over a year ago

This is not true. The draw() function does not have to be reentrant. It is one possible solution in this particular case, but Processing's draw() function does not have to be reentrant at all.

Collectives™ on Stack Overflow

nested for loop - Processing (java)

2 Answers 2

2 Comments

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related