Extract folder name from path in batch file

Question

I want to traverse all files within a specific directory and all its subdirectories and then print out the folder name of each file.

I don't know how to get the folder name of each file.

FOR /F "delims=" %%x IN ('dir /B /A /S *') DO (
    :: Suppose %%x is 'C:\myfolder\a.txt', the desired output is 'myfolder'
    :: %%~nx is not correct
    echo ???
)

n is for filename. Check for /? for other options. You can combine the different options. You probably look for %%~dpx — Stephan
– Stephan, Commented Jan 22, 2016 at 15:39
Please note that DOS is an Operating System from the 80s/90s! Please use the tag Windows instead. — user6250760
– user6250760, Commented Aug 23, 2017 at 6:01

Stephan · Accepted Answer · 2016-01-22 16:21:17Z

4

If you want just the path (without drive, without filename), %%~px is what you need

If you want just the last folder, not the complete path. This is indeed not that trivial:

@echo off 
setlocal enabledelayedexpansion
for /f "delims=" %%x in ('dir /b /a /s *') do (
  set "line=%%~dpx"
  for /f "delims=" %%y in ("!line:\=.!") do set folder=%%~xy
  echo %%~nxx is in:  !folder:~1!
)

answered Jan 22, 2016 at 16:21

Stephan

56.8k11 gold badges66 silver badges97 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Dennis van Gils Over a year ago

Did I just beat the almighty Stephan by 31 seconds? Oh my.

Stephan Over a year ago

"almighty"? There are other names here that come to my mind :D Nevertheless - your's is better (assuming we understood the question right)

Squashman Over a year ago

@Stephan, your inner FOR can just be this: for %%y in ("%%~dpx\.") do echo %%~nxy. Your inner FOR will have problems with Folders that are named with periods. I just noticed that is what Dennis did but his also suffers from the periods.

Dennis van Gils · Accepted Answer · 2016-01-22 19:57:36Z

3

I think this is what you're looking for:

@echo off
FOR /F "delims=" %%F IN ('dir /B /A /S *') DO (
for %%D in ("%%~dpF\.") do echo %%~nxD
)
pause

edited Jan 22, 2016 at 19:57

answered Jan 22, 2016 at 16:20

Dennis van Gils

3,4712 gold badges16 silver badges35 bronze badges

3 Comments

Squashman Over a year ago

Your ECHO needs the x modifier as well otherwise it will not be able to handle folder names with periods.

Dennis van Gils Over a year ago

@Squashman you're right, to be honest the first version had that but I forgot what it was for and removed it

useprxf Over a year ago

Thanks, this is what I want.

Collectives™ on Stack Overflow

Extract folder name from path in batch file

2 Answers 2

3 Comments

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related