Accessing clojure macro via namespace in which it was not defined

Question

I've defined a macro in func.clj:

(ns my-library.func)

(defmacro my-macro [arg]
  `(identity ~arg))

and I want to bind it to a variable in core.clj:

(ns my-library.core
  (:require [my-library.func :as func])

(def my-macro-core func/my-macro)

so that I can do something like the following:

(ns script.core
  (:require [my-library.core :as mlc]))

(mlc/my-macro-core :boring-macro) ; -> :boring-macro

However, I can't do that because macros don't evaluate to a value. The following works:

(ns my-library.core
  (:require [my-library.func :as func])

(defmacro my-macro-core [arg]
  `(func/my-macro ~arg))

but it's redundant, so I was wondering if there's a cleaner way to do this.

jgpc42 · Accepted Answer · 2016-01-25 06:15:35Z

2

It's a bit of a hack, but it can be done:

(ns my-library.func)

(defmacro my-macro [arg]
  `(identity ~arg))

(ns my-library.core
  (:require [my-library.func :as func]))

(def ^:macro my-macro-core @#'func/my-macro)

(ns script.core
  (:require [my-library.core :as mlc]))

(mlc/my-macro-core :boring-macro)

The trick is to set the new var being defined to the raw function value of the macro being aliased, while setting the :macro metadata flag so the compiler recognizes it and calls it appropriately.

answered Jan 25, 2016 at 6:15

jgpc42

611 silver badge4 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

aadah Over a year ago

It seems that the @ is unnecessary. For example, (def ^:macro my-or #'or) yields a new macro my-or which works exactly like or. What is that? Thanks for the answer again.

jgpc42 Over a year ago

The way I posted just avoids Var indirection. Using the var itself is useful if you want subsequent updates to the var's value to be reflected in aliases.

gfredericks · Accepted Answer · 2016-01-25 21:10:20Z

0

Potemkin's import-vars supports macros:

(require '[potemkin :refer [import-vars]])
(import-vars [my-library.core my-macro])

edited Jan 25, 2016 at 21:10

answered Jan 25, 2016 at 16:07

gfredericks

1,3326 silver badges11 bronze badges

Collectives™ on Stack Overflow

Accessing clojure macro via namespace in which it was not defined

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related