Regex on a string

The expression (.*\w+) will match up to the last word character in the line. What you are looking for is most likely this ([0-9a-z:]+)

Guessing from your comment in reply to ikegami, maybe the following will give results you want.

#!/usr/bin/perl
use strict;
use warnings;

my @keys = qw/ rw ro root /;
my $wanted = join "|", @keys;

my %data;

while (<DATA>) {
    my ($path, $param) = split;
    my ($vol, $q) = (split '/', $path)[2,3];

    my %tmp = map {split /=/} grep /^(?:$wanted)/, split /,/, $param;

    $data{$vol}{$q // ' '} = \%tmp;
}

use Data::Dumper; print Dumper \%data;

__DATA__
/vol/vol1   -sec=sys,rw=h1:h2,anon=0
/vol/vol1/q1 -sec=sys,rw=h3:h4,anon=0,ro=h1:h2
/vol/vol2/q1  -sec=sys,root=host5,ro=h3:h5,rw=h1:h2,anon=0

The output from Data::Dumper is:

$VAR1 = {
          'vol2' => {
                      'q1' => {
                                'ro' => 'h3:h5',
                                'root' => 'host5',
                                'rw' => 'h1:h2'
                              }
                    },
          'vol1' => {
                      ' ' => {
                               'rw' => 'h1:h2'
                             },
                      'q1' => {
                                'ro' => 'h1:h2',
                                'rw' => 'h3:h4'
                              }
                    }
        };

Update: can you tell me what does (?:) mean in the grep?

(?: . . .) is a non-capturing group. It is used in this case because the beginning of the regex has ^. Without grouping, the regex would attempt to match ro positioned at the beginning of the string or rw or root anywhere in the string (not just the beginning).

/^ro|rw|root/ rather than /^(?:ro|rw|root)/

The second expression helps the search along because it knows to only attempt a match at the beginning of the string for all 3 patterns and not to try to match anywhere in the string (speeds things up although in your case, there are only 3 alternating matches to attempt - so, wouldn't make a huge difference here). But, still a good practice to follow.

what does (// ' ') stand for?

That is the defined or operator. The expression $q // ' ' says to use $q for the key in the hash if it is defined or a space instead.

You said in your original post I'm trying to capture the second and third groups (if it is a space it should return a space).

$q can be undefined when the split, my ($vol, $q) = (split '/', $path)[2,3]; has only a vol and not a q such as in this data line (/vol/vol1 -sec=sys,rw=h1:h2,anon=0).

No idea what you want, but a regex would not make a good parser here.

while (<DATA>) {
   my ($path, $opts) = split;
   my %opts =
      map { my ($k,$v) = split(/=/, $_, 2); $k=>$v }
         split(/,/, $opts);

   ...
}

(my %opts = split(/[,=]/, $opts); might suffice.)