ActionScript 3 Can't Add and Remove item from Array

It's easier to identify the cause of the problem if you provide a complete and verifiable example, however, at the heart of your issue is an understanding of the Array methods:

1. splice(startIndex:int, deleteCount:uint), for removing items.
2. push(... args), for adding items.

If you explicitly reference newItems[0] thru [5], then you'll only ever affect entries 0 - 5, however, push is useful since it simply adds it to the end of your array. Conversely, you could use either splice (to specifically target a certain index), or pop() (which removes the last element from an array) to delete items from your array.

The other problem is that your arrays are local. Because you're recreating them every time you call RemoveItems or AddItem, you'll never save your changes. So, move it outside of those functions, and it'll be saved between clicks.

I've reworked your code with changes, and added supplemental code for the missing UI code you didn't provide. You can run this in a new .fla file and it will work as intended.

import flash.text.TextField;
import flash.events.KeyboardEvent;
import flash.display.Sprite;

var items:Array = ["Bread", "Dog Food", "Eggs", "Hamburger", "Milk"];

function addItem(e:MouseEvent):void {
    if (input_txt.text != "") { // Assuming we having something in the input_txt,
        items.push(input_txt.text); // add it to the end of our items array
        input_txt.text = "";
        updateOutput();
    }
}

function removeItems(e:MouseEvent):void {
    items.splice(0,1);
    updateOutput();
}

function clearList(e:MouseEvent):void {
    items = []; // empty our list by replacing it with a new one.
    output_txt.text = "";
    totalItems_txt.text = "0";
}

function updateOutput():void {
    items.sort(Array.CASEINSENSITIVE);
    output_txt.text = "";
    for (var i:int = 0; i < items.length; i++){
        output_txt.appendText(items[i] + "\n");
    }
    totalItems_txt.text = "Total: " + items.length;
}



/* Supplemental UI Creation */

var addItem_btn:Sprite = new Sprite();
addItem_btn.graphics.beginFill(0xa1FFa1,1);
addItem_btn.graphics.drawRect(0,0,100,25)
addChild(addItem_btn);
addItem_btn.addEventListener(MouseEvent.CLICK, addItem);

var clear_btn:Sprite = new Sprite();
clear_btn.graphics.beginFill(0xa1a1a1,1);
clear_btn.graphics.drawRect(0,0,100,25)
addChild(clear_btn);
clear_btn.x = 101;
clear_btn.addEventListener(MouseEvent.CLICK, clearList);

var remove_btn:Sprite = new Sprite();
remove_btn.graphics.beginFill(0xFFa1a1,1);
remove_btn.graphics.drawRect(0,0,100,25)
addChild(remove_btn);
remove_btn.x = 202;
remove_btn.addEventListener(MouseEvent.CLICK, removeItems);

var input_txt:TextField = new TextField();
addChild(input_txt);
input_txt.type = "input";
input_txt.text = "input_txt";
input_txt.y = 50;

var output_txt:TextField = new TextField();
addChild(output_txt);
output_txt.text = "output_txt";
output_txt.y = 50;
output_txt.x = 101;

var totalItems_txt:TextField = new TextField();
addChild(totalItems_txt);
totalItems_txt.text = "totalItems_txt";
totalItems_txt.y = 50;
totalItems_txt.x = 202;

All you had to do is declare your array as public and then add just the values to the array by using push(). when you sort the actual index of the array still remains , but the displayed items index will be different ,