Replace repetitions of specific text with perl script

Introduce the 'current label' -- the latest one picked up -- and keep track of it. Once a line with a label comes up compare: if it is the same it repeats so delete it, otherwise replace it and we have the new 'current' one.

The processing goes line-by-line. Alternatively, one can read a whole block at a time to enable per-block processing, which may be more convenient. Code for this is shown at the end.

use warnings;
use strict;

open my $fh_out, '>', 'new_text_label.txt';
open my $fh_in, '<', 'text_label.txt';

# Our current (running) label
my $curr_label = '';

while (<$fh_in>)  
{
    # If line with label fetch it otherwise (print and) skip
    my ($label) = $_ =~ m/txt@#(\w+)/;
    if (not $label) {
        # ... process non-label line as needed ...
        print $fh_out $_;
        next;
    }       
    # Delete if repeated (matching the current), reset if new
    if ($curr_label eq $label) {
        s/(txt@)(?:#\w+)(.*)/$1$2/;
    }   
    else {
        $curr_label = $label;
    }   
    # ... process label-line as needed ...
    print $fh_out $_;
}

This yields the required file. Processing of lines with or without a label is separate, which may be good if further processing differs for them. Or, the pre-processing of the label-line can be all done in one place, which is better if further processing does not distinguish between lines with or without a label.

while (<$fh_in>) 
{
     # If this is the label line, process it: delete or replace the label
     if (my ($label) = $_ =~ m/txt@#(\w+)/) {
        # Delete if repeated (matching the current), reset if new
        if ($curr_label eq $label) {
            s/(txt@)(?:#\w+)(.*)/$1$2/;
        }   
        else {
            $curr_label = $label;
        }
     }
     # The label is now fixed as needed. Process lines normally ...
     print $fh_out $_;
}

This replaces the while loop above, the rest of the code is the same.

Derived from what was originally posted, commented

Here are changes in the code so that it reads the whole block at a time, which is good for processing that can make use of having the whole block of text in the variable. Note that a block contains new lines (so regexes may need /s etc). To enable possible bulk processing all blocks are first read into an array as well.

my @blocks = do { 
    # Set record separator to empty line to read blocks
    local $/ = "\n\n";
    open my $fh_in, '<', 'text_label.txt';
    <$fh_in>;    
};

# Our current (running) label
my $curr_label = '';

foreach my $bl (@blocks) 
{
     # The label pre-processing is exactly the same as above
     # Other processing can now utilize having the whole block in $bl
}