I'm using PASCAL for a course i'm doing and i'm having trouble with an assignment, in my program i'm using 2 arrays that uses a variable from a user's input but when i go to run the program it comes up with, Error: Can't evaluate constant expression. The code for the array is:
Var
x : integer;
s : array[1..x] of real;
n : array[1..x] of string[30];
Here x is the user's input, is there a way for an array to go from 1 to x?
If x is a variable, that won't work indeed. The range of a so called static array must be a constant expression, i.e. it must be known at compile time.
So what you want won't work, as is.
In FreePascal, you can use dynamic arrays, though. Their lengths can be set and changed at runtime.
var
x: Integer;
s: array of Real;
n: array of string[30]; // why not just string?
and later:
x := someUserInput(); // pseudo code!
SetLength(s, x);
SetLength(n, x);
You should be aware of the fact that dynamic arrays are 0-based, so your indexes run from 0 up to x - 1. But for the limits of the array, you should rather use Low() and High() instead:
for q := Low(s) to High(s) do
// access s[q];
(Low() and High() are not the topic, but just know they can also be used for static arrays, and that they return the actual array bounds -- I always use High and Low for this)
a - b is subtraction.Here is not so simple as using managed types like dynamic arrays suggested by @RudyVelthuis but more funny solution providing some comprehension about how it works internally :)
program dynarr;
{$mode objfpc}{$H+}
type
TArrayReal = array[1..High(Integer)] of Real;
TArrayString30 = array[1..High(Integer)] of string[30];
PArrayReal = ^TArrayReal;
PArrayString30 = ^TArrayString30;
var
i: Integer;
x: Integer;
s: PArrayReal;
n: PArrayString30;
begin
Write('Count: '); Readln(x);
// Allocate memory for the actual count of the elements
s := GetMem(SizeOf(Real) * x);
n := GetMem(SizeOf(string[30]) * x);
try
for i := 1 to x do
begin
Write('Row ', i:3, ': '); Readln(s^[i], n^[i]);
end;
Writeln('Your input was:');
for i := 1 to x do
Writeln('Row ', i:3, ': ', s^[i]:10:3, n^[i]: 20);
finally
// Do not forget to release allocated memory
FreeMem(s);
FreeMem(n);
end;
end.
The limits of an array must be known at the point in time the array is instantiated.
That means you cannot declare your array’s length x and the array itself within the same block.
You need to declare and define x in a surrounding block:
program variableLengthArrayDemo(input, output);
type
natural = 1..maxInt;
var
count: natural;
procedure processData;
var
data: array[1..count] of real;
begin
end;
begin
write('Enter total count of data points: ');
readLn(count);
processData
end.
You may make count a routine parameter, it is still the outside block.
Another more elaborate, yet more powerful method uses Extended Pascal schema data types.
Note, the shown program requires a processor complying with the requirements of ISO standard 10206 “Extended Pascal”.
Unfortunately, as of 2024 the FreePascal Compiler intends to, but does not (yet) entirely support EP, in particular above program is not accepted even in {$mode extendedPascal}.
{$mode extendedPascal} that is meant to support Extended Pascal eventually. Also tag freepascal is not the only tag, but there is also tag pascal.
;?