Nested Loop in VBA not working, because of different for loops?

No offence, but your code (and coding style) is a mine field.

This part Sheets("Sheet1").Range(r, "A").Value will throw error 1004, Range cant take two params as Row and Columns, Cells can. Change it to : Sheets("Sheet1").Cells(r, "A").Value

Second, if Cells(r, "A").Value is blank/empty Navigate will throw error 5. Check for a non empty value before navigating.

Same range issue, error 1004 for Range(r, "C").Value

Not writing address: It will not write anything in column C because of your ill constructed inner for loop. When a condition is met, you are jumping out of the loop before writing the value in cells.

Here

 If Len(dd) > 0 Then Exit For
      'Gives a confirmation message and writes the result to a cell
      ws.Cells(r,"C").Value = dd

if length of dd is > 0 it will never reach the statement, ws.Cells(r,"C").Value = dd

Change it to:

 If Len(dd) > 0 Then
        'Gives a confirmation message and writes the result to a cell
         ws.Cells(r,"C").Value= dd
        Exit For
      End If

Bonus: Learn and start using F8

One issue that will definitely give you an error is how you are using range.

When using range for your code you would need to use the following:

IE.navigate Sheets("Sheet1").Range("A" & r).Value

Then of course you would need to print out the same way

Range("C" & r).Value = dd

now a couple of hints that you can place in your code to make it more efficient,

Private Sub CommandButton1_Click()

  Dim IE As Object, r as integer
  Dim wb as Workbook, ws as Worksheet
  Dim dd as String, c as Variant, found as Boolean

  'Create InternetExplorer Object
  Set IE = CreateObject("InternetExplorer.Application")
  'create other objects
  Set wb = ThisWorkbook
  Set ws = wb.Worksheets("Sheet1")


  ' You can uncoment Next line To see form results
  IE.Visible = False

  'START LOOP
  ' URL to get data from
  For r = 2 To 3
    debug.print ws.Range("A" & r).Value 'see what the url is
    IE.navigate ws.Range("A" & r).Value
    Do while IE.ReadyState <> 4: DoEvents: Loop
    'page loaded.
    ' Runs loops to look for the value within the classname, if classname alternates it will change the element, if null it will exit
    found = false
    For each c in Array("vk_sh vk_bk", "_Xbe")
      On Error Resume Next
      dd = IE.document.getElementsByClassName(c)(0).innerText
      On Error GoTo 0
      If Len(dd) > 0 Then
        found = true
      End If
      If found Then
        ws.Range("C" & r).Value = dd
        dd = ""  'need to set to nothing or it will retain the value.
        Exit For
      End If
    Next c
  Next r

  IE.Quit

'Clean up
Set IE = Nothing


End Sub

There are definitely more ways to do what you are after but fix up those 2 things. If you need more help post your workbook.

Thanks

EDIT: I made some changes to the above code. It looks like you may have been exiting your loop too quickly. I was able to get the URLs you provided to work using this.

There seems to be 2 issues with your code. I have not tried, but looking at your code

1. Range is defined as cell1, cell2. Cell Address is "A2", "A3" etc. so in your code you might need to do Range("A" & r) to concatenate the row with the column.
2. Even after that you will have an issue. When you Navigate to a URL, You need to wait until the document is loaded. You have to either do some event driven code or loop until the document state is ready or something. Otherwise you will not be able to parse and read the contents of the loaded document.