How can I filter an array without using a loop in Perl?

Question

Here I am trying to filter only the elements that do not have a substring world and store the results back to the same array. What is the correct way to do this in Perl?

$ cat test.pl
use strict;
use warnings;

my @arr = ('hello 1', 'hello 2', 'hello 3', 'world1', 'hello 4', 'world2');

print "@arr\n";
@arr =~ v/world/;
print "@arr\n";

$ perl test.pl
Applying pattern match (m//) to @array will act on scalar(@array) at
test.pl line 7.
Applying pattern match (m//) to @array will act on scalar(@array) at
test.pl line 7.
syntax error at test.pl line 7, near "/;"
Execution of test.pl aborted due to compilation errors.
$

I want to pass the array as an argument to a subroutine.

I know one way would be to something like this

$ cat test.pl 
use strict;
use warnings;

my @arr = ('hello 1', 'hello 2', 'hello 3', 'world1', 'hello 4', 'world2');
my @arrf;

print "@arr\n";

foreach(@arr) {
    unless ($_ =~ /world/i) {
       push (@arrf, $_); 
    }
}
print "@arrf\n";

$ perl test.pl
hello 1 hello 2 hello 3 world1 hello 4 world2
hello 1 hello 2 hello 3 hello 4
$

I want to know if there is a way to do it without the loop (using some simple filtering).

Ruel · Accepted Answer · 2010-10-18 14:16:00Z

39

That would be grep():

#!/usr/bin/perl

use strict;
use warnings;

my @arr = ('hello 1', 'hello 2', 'hello 3', 'world1', 'hello 4', 'world2');
my @narr = ( );

print "@arr\n";
@narr = grep(!/world/, @arr);
print "@narr\n";

answered Oct 18, 2010 at 14:16

Ruel

15.8k7 gold badges41 silver badges49 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Greg Bacon · Accepted Answer · 2010-10-18 14:41:06Z

13

Use grep:

sub remove_worlds { grep !/world/, @_ }

For example:

@arrf = remove_worlds @arr;

Using grep is the most natural fit for your particular problem, but for completeness, you can also do it with map:

sub remove_worlds { map /world/ ? () : $_, @_ }

It's a bit klunky here, but map gives you a hook in case you want to process the filtered elements before discarding them.

answered Oct 18, 2010 at 14:41

Greg Bacon

141k34 gold badges196 silver badges253 bronze badges

2 Comments

Wolf Over a year ago

Good to have the ref links here.

davenpcj Over a year ago

That !/match/ negative matching syntax was critical. I'd been considering map and other solutions but they all seemed too clunky for perl.

Andy Lester · Accepted Answer · 2010-10-18 14:13:20Z

11

Use grep

@no_world_for_tomorrow = grep { !/world/ } @feathers;

For details, perldoc -f grep.

answered Oct 18, 2010 at 14:13

Andy Lester

94.2k16 gold badges106 silver badges162 bronze badges

Comments

codaddict · Accepted Answer · 2010-10-18 14:20:18Z

5

You can use the grep function as:

@arrf =  grep(!/world/, @arr);

The expression !/world/ is evaluated for each element of the array @arr and a list of elements which which the expression evaluated to be true is returned.

The expression /world/ searches for the word world and is true it's present. And the expression !/world/ is true if the string world is absent.

edited Oct 18, 2010 at 14:20

answered Oct 18, 2010 at 14:14

codaddict

457k83 gold badges501 silver badges537 bronze badges

Collectives™ on Stack Overflow

How can I filter an array without using a loop in Perl?

4 Answers 4

Comments

2 Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

2 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related