Using batch file give exit code according to log file

Question

I get a log file at the end of my build which indicates the status of the projects I build, I want to use this log file to give me exit code 1 when failed builds are not equal to 0.

Log file:

========== Build: 19 succeeded, 0 failed, 0 up-to-date, 0 skipped ==========

How do I create a batch file that sees if there are 1 failed(or more), and set %ERRORLEVEL%=1.

npocmaka · Accepted Answer · 2016-09-21 13:12:30Z

2

Not tested:

set "log=log.txt"

for /f "tokens=5 delims= " %%# in ('find "========== Build:" "%log%" ') do set /a fails=%%#

if %fails% neq 0 exit /b 1

answered Sep 21, 2016 at 13:12

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

dbenham Over a year ago

It might be nice to capture the failure count, but the OP did not ask for it. If a simple binary Success or Failure detection is the goal, then only a single FINDSTR is all that is needed.

dbenham · Accepted Answer · 2016-09-21 16:37:25Z

2

If all you want to do is set ERRORLEVEL to 0 upon success, and 1 if there was at least one failure, then a simple FINDSTR is all that is needed.

findstr /rc:"^========== Build: .* succeeded, 0 failed," "log.txt" >nul

ERRORLEVEL will be 0 if the string was found, 1 if not.

You can conditionally take action based on success or failure by using the && and || operators

findstr /rc:"^========== Build: .* succeeded, 0 failed," "log.txt" >nul && (
  rem Success actions go here
) || (
  rem Failure actions go here
)

So if you want to simply exit with an ERRORLEVEL of 1 if there was a failure, you could use:

findstr /rc:"^========== Build: .* succeeded, 0 failed," "log.txt" >nul || exit /b 1

answered Sep 21, 2016 at 16:37

dbenham

132k29 gold badges273 silver badges410 bronze badges

Collectives™ on Stack Overflow

Using batch file give exit code according to log file

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related